Convert character date to YYYYMMDD date field

[mlogan]

Hi All,

My date field (Imported from Excel) written like 2/30/2015 and have $10. format. Can someone help me to convert it to 20150230 format please. Thanks,

[FreelanceReinh · Accepted solution]

Hi @mlogan,

I would create SAS date values from those character dates:

data _null_;
length c $10;
c='3/30/2015';
d=input(c,mmddyy10.);
format d yymmddn8.;
put d;
run;

If you need a character string in YYYYMMDD format you can apply the PUT function to the SAS date value:

dc=put(input(c,mmddyy10.),yymmddn8.);

For invalid dates the conversion will fail, though. 🙂

[mlogan]

Thanks Reinhard.

[mlogan]

Hi Reinhard,
Would you please tell me what I have to do if I want to convert the existing column to YYMMDDN8. format without making a new column. Here in your example converting column 'c' without making a new column 'd'.

[FreelanceReinh]

You could drop the old (character) variable and rename the new (numeric) one:

data have;
length c $10;
c='3/30/2015';
run;

data want;
set have;
d=input(c,mmddyy10.);
format d yymmddn8.;
drop c;
rename d=c;
run;

If your goal is a character variable (such as DC in my previous post), you could overwrite the existing value directly, because no type conversion would occur:

data want;
set have;
c=put(input(c,mmddyy10.),yymmddn8.);
run;

However, this would leave the length of the variable at 10, although 8 would be sufficient. To avoid this, you could define a new variable with length 8 and then drop and rename as shown above.

[mlogan]

Thanks Reinhard, I did not know this drop trick. Very helpful.