Combining explicit and implicit loop

[SAS_inquisitive]

Hello,

How does this program execute?

data test;
	set sashelp.class;

	do until(eof);
		set sashelp.class end=eof;
	 output;
	end;
run;

[Kurt_Bremser]

Try it, and read the log. If puzzled, come back here.

[mkeintz]

Form a hypothesis test it, report the results, and why you think those results occurred.  Then you'll get plenty of responses.

[SAS_inquisitive]

@KurtBremser and @mkeintz I was wondering why two records are reading from first set statement?

[mkeintz]

1. How many times do you think the complete loop    "do until (eof); ....... " is successfully run?
   
   
2. What happens when a SET statement attempts to read beyond end of data?

[SAS_inquisitive]

@mkeintz  1.  "do until (eof); ....... "  runs just in one loop as it is DOW-LOOP setting.

                   2.  _n_ increments by 1 and implicit loop terminates.

data test;
    put _all_;
	set sashelp.class;
	put _all_;
run;

data test;
	
	put _all_;
	do until(eof);
      
		set sashelp.class end=eof;
		output;
    put _all_;
	end;
	
run;

[ballardw · Accepted solution]

Look at the log after running this and see if you get any enlightenment:

data test;
	set sashelp.class;
   put 'Before loop';
	do until(eof);
      put 'At begin of loop' +1 name=;
		set sashelp.class end=eof;
      put 'In loop after set' +1 name=;
	 output;
      put;
	end;
run;

[Rick_SAS]

Building on ballardw's advice, try

data test;
	set sashelp.class(rename=(Name=FirstName));
   put 'Before loop';
	do until(eof);
      put 'At begin of loop' +1 FirstName=;
		set sashelp.class end=eof;
      put 'In loop after set' +1 FirstName= +1 name=;
	 output;
      put;
	end;
run;

[SAS_inquisitive]

@Rick_SAS, renaming helped understand since the original solution was given by @Ballard, I accepted his solution. Thanks .

[Kurt_Bremser]

A nice variation to further illustrate the behaviour of set statements and loops:

data test;
  set sashelp.class;
  do while (not eof);
    set sashelp.class end=eof;
    output;
  end;
run;

[PGStats]

The question you may want to ask instead is When does this program stop?

[SAS_inquisitive]

@PGStats, you are absolutely right.