Clear contents of csv file

[Citrine10]

Hi there, 

How can I clear contents of a csv file? I dont want it to delete the file, instead it must just empty the file so that I have a blank file.

[Kurt_Bremser]

Just create it anew with the FILE statement in a data step:

data _null_;
set sashelp.class;
file "~/test.csv" dlm=",";
put name sex age;
run;

data _null_;
length fref $8;
rc = filename(fref,"~/test.csv");
fid = fopen(fref);
do i = 1 to foptnum(fid);
  optname = foptname(fid,i);
  infitem = finfo(fid,optname);
  put optname "=" infitem;
end;
rc = fclose(fid);
rc = filename(fref);
run;

data _null_;
file "~/test.csv";
run;

data _null_;
length fref $8;
rc = filename(fref,"~/test.csv");
fid = fopen(fref);
do i = 1 to foptnum(fid);
  optname = foptname(fid,i);
  infitem = finfo(fid,optname);
  put optname "=" infitem;
end;
rc = fclose(fid);
rc = filename(fref);
run;

[s_lassen · Accepted solution]

You can do it with a datastep, e.g.

filename csvfile '<path to file>';

data _null_;
  file csvfile old;
run;

By specifying the OLD disposition for the file and writing nothing to it, it gets cleared.