Let's try to piece together what you might have run from the various posts you have shown.
First you have this macro definition:
%macro set_conditions;
%let location = 'LOCA1';
%if &week_day. = 2 %then %let location = ('LOCA1', 'LOCA2', 'LOCA3');
%if &week_day. = 5 %then %let location = ('LOCA1', 'LOCA4', 'LOCA5', 'LOCA6');
%mend;
We'll come back to this.
Then you have this data step:
data setup;
attrib run_date length=8 format=mmddyy10.;
run_date = today();
day_of_week = weekday(run_date);
call symputX("run_date",run_date);
call symputX('day_of_week',day_of_week);
run;
I corrected the code to use CALL SYMPUTX so RUN_DATE and DAY_OF_WEEK will have a values like 23537 and 2 instead of including lots of unneeded leading spaces.
Then you call the macro:
%set_conditions;
Which should cause an error since you never gave the macro variable WEEK_DAY any value.
And finally you run some SQL code
proc sql;
create table want_01 as
select count_date
, case when location_code = 'LOCAX' then 'LOCA1'
else location_code
end as location_code,
from have
where location_code in (&location.)
;
quit;
That is referencing a macro variable LOCATION that you did not create since the %LET's in the macro SET_LOCATION never executed. But even it they had since you never told SAS to make LOCATION as a GLOBAL macro variable it disappeared when the macro SET_CONDITION finished running.
If you want to write a macro that takes as input a week day number and then sets a macro variable it would probably be best to write the macro as having two input parameters. The value of the week day number and the name of the macro variable to create. Also the value should look the same whether it has one, two or more values. So something like:
%macro set_conditions(week_day,mvar=location);
%if not %symexist(&mvar) %then %global &mvar;
%let &mvar = 'LOCA1';
%if &week_day. = 2 %then %let &mvar = 'LOCA1' 'LOCA2' 'LOCA3';
%if &week_day. = 5 %then %let &mvar = 'LOCA1' 'LOCA4' 'LOCA5' 'LOCA6';
%mend set_condition;
Which you could call passing in the value of the macro variable you did create:
data setup;
attrib run_date length=8 format=mmddyy10.;
run_date = today();
day_of_week = weekday(run_date);
call symputX("run_date",run_date);
call symputX('day_of_week',day_of_week);
run;
%set_conditions(&day_of_week)
And now LOCATION will exist and have a valid value to use in the expression:
where location_code in (&location.)
