Bubble plot

[EMB]

I am trying to produce a bubble plot to show agreement between 2 raters assessing a clinical score (integer number). I defined x as the 1st rater score and y as the 2nd rater score. My question is how to define ‘size’ so that the bubbles size represent the number of cases with agreement between both raters? Thanks!

[PGStats]

A simple example:

data fake;
call streaminit(743439);
/* There are 5 possible ratings. Rater2 disaggrees with Rater1 20% of the time */ 
do case = 1 to 100;
    rate1 = rand("integer", 5);
    if rand("bern", 0.2) then rate2 = rand("integer", 5);
    else rate2 = rate1;
    output;
    end;
run;

proc sql;
create table ratings as
select rate1, rate2, count(*) as n
from fake
group by rate1, rate2;
quit;

proc sgplot data=ratings;
bubble x=rate1 y=rate2 size=n / proportional transparency=0.3;
run;

[ballardw]

If you show some example of your current data we might have some clues.

Basically you need to calculate that count (or rate) from your data and without knowing what your data looks like we can't provide anything targeted to your situation.