Assigning Missing Values Irrespective of Type

[slolay]

Hi

Is it possible to assign values to missing without knowing the variable's type?

A function that would assign a '' or . itself and I do not have to explicitily type it.  I have some variables and do not want to have to find out which each type is  and then assign them either '' or . myself.

Something like

     textvar=missing;

     numvar=missing;

ie set it to the appropriate missing value

Thanks in advance

Steve

[art297]

You can use call missing.  e.g.,

call missing(textvar)

would work as would

call missing(numvar)

[slolay]

Thanks Art...

sorry but don;t really understand.  Do you have an example

Maybe it will be clearer when I give an example too..

data .....;

set.....;

if not first.subject then do;

     age=.;

     sex=.;

     telno='';

     address='';

end;   

run;

Thanks

Steve

[art297 · Accepted solution]

There are some shortcuts you could use, but the brute force method of applying call missing might be:

data .....;

set.....;

if not first.subject then do;

     call missing(age);

     call missing(sex);

     call missing(telno);

     call missing(address);

end;  

run;

[slolay]

Thanks Art

Steve

[art297]

And, depending upon what you want to do, you can use call missing with arrays.  E.g., while the following probably isn't close to your problem, it may show you some of the versatility.  It takes sashelp.class and, for every other record, either sets the character fields or the numeric fields to missing:

data test;

  set sashelp.class;

  array numbers(*) _numeric_;

  array characters(*) _character_;

  if mod(_n_,2) eq 1 then do;

    call missing(of numbers(*));

  end;

  else do;

    call missing(of characters(*));

  end;

run;

[Peter_C]

shortcuts that Art297 refers to are great try

if not first.subject then call missing( age, sex, telno, address );

or

%let varlist = age sex telno address ;

if not first.subject then call missing( of &varlist ) ;