I think you are saying that you are given a weekly schedule, showing specific days of the week for a given event. And you want to calculate the number of days between each event and the most recent event, correct? And the first event for a given week follows the last event for the prior week, which had the same schedule as the current week, yes?
Then:
data schedules;
input sch1 sch2 sch3;
datalines;
2 4 6 /* M W F*/
1 3 5 /* Su Tu Th */
1 3 6 /* Su W Sa */
run;
data want (drop=s);
set schedules;
array _sch {*} sch1-sch3;
array _days {*} days1-days3;
do s=1 to dim(_sch);
if s=1 then _days{s}= _sch{1}+7 - _sch{dim(_sch)} ;
else _days{s}=_sch{s}-_sch{s-1};
end;
run;
By using the "if s=1" statement, you don't really need to do mod7 arithmetic.
Editted supplement: But if you really want to do MOD arithmetic, you can do it both on the array declaration (mod 3) and the result (mod 7):
data want2 (drop=s);
set schedules;
array _sch {*} sch1-sch3;
array _days {*} days1-days3;
do s=1 to dim(_days);
_days{s}= mod(_sch{s}+7 - _sch{mod(s+1,3)+1},7);
end;
run;
In the case of the MOD7 component, you don't need to worry about generating a 7-day interval (which would be zero mod 7), since we assume three dates per week, with ascending values. But you do need to do an adjustment for the MOD3 component - this avoids trying to subtract _SCH{1} minus _SCH{0} - which doesn't exist.
But even that can be avoided by changing the definition of the _SCH array. This is probably the simplest code that avoid using an IF test:
data want3 (drop=s);
set schedules;
array _sch{0:3} sch3 sch1-sch3;
array _days {*} days1-days3;
do s=1 to dim(_days);
_days{s}= mod(_sch{s}+7 - _sch{s-1},7);
end;
run;
The "trick" here is to define the _SCH array to have 4 elements, starting not at element 1, but at element 0 (which has the same value as element 3). So when the array index S=1 you will get _days{1} = _sch{1}+7 - _sch{0} modulo 7.
