You do not have to process each site separately. If you sort your input, it can be done with BY group processing as well.
Here is an example using SASHELP.CLASS as the input, and SEX as the BY group (instead of your SITE):
proc sort data=sashelp.class out=start;
where age<14;
by sex;
run;
data initial;
do count=1 by 1 until(last.sex);
set start;
by sex;
end;
N1=int(count/2);
if mod(count,2)=1 then
N1=N1+round(rand('uniform'));
N2=count-N1;
do until(last.sex);
set start;
by sex;
if N1>0 and rand('uniform')<=N1/(N1+N2) then do;
tp=1;
N1=N1-1;
end;
else do;
tp=2;
N2=N2-1;
end;
output;
end;
drop count N1 N2;
run;
What it does: the first DO loop simply counts the number of participants in each BY group.
After that, half is assigned to each type (TP variable), if the count is odd, the odd one out is randomly assigned to one of the groups.
So, before the next loop, the number that we want of each type is in the variables N1 and N2.
In the second loop, the participants in the BY group are randomly assigned to the two types. We keep counting down N1 and N2, so that the correct total number will be assigned to each group.
Now, when you get more data, we can simulate that by adding the rest of SASHELP.CLASS:
data all;
set initial sashelp.class(where=(age>=14));
run;
You could also use a PROC APPEND or a MERGE (by first sorting by the BY group (here: SEX) and the unique id (here: NAME).
Sort your new dataset:
proc sort data=all;
by sex;
run;
And then do just about the same thing as before:
data want;
count1=0;
count2=0;
do count=1 by 1 until(last.sex);
set all;
by sex;
select(tp);
when(1) count1+1;
when(2) count2+1;
otherwise;
end;
end;
N1=int(count/2);
if mod(count,2)=1 then
N1=N1+round(rand('uniform'));
N2=count-N1;
N1=N1-count1;
N2=N2-count2;
do until(last.sex);
set all;
by sex;
if missing(tp) then do;
if N1>0 and rand('uniform')<=N1/(N1+N2) then do;
tp=1;
N1=N1-1;
end;
else do;
tp=2;
N2=N2-1;
end;
end;
output;
end;
drop count: N1 N2;
run;
The difference this time is that we also count the number of participants already assigned, and subtract that from the calculated N1 and N2.
I did this using the RAND function, which is a better random number generator than RANUNI. If you want to be able to replicate your results (getting the same distribution in two separate runs) you should use CALL STREAMINIT in the beginning of each data step.
EDIT note: I added the condition N1>0 to the condition in the second loop, just in case the RAND function returns a 0 value (I am not quite sure if it can).
