1. Modify the Macro definition to include the parameters of Subject and Period based on your data
2. Move the SQL step into the macro to calculate BaseY in the macro.
3. Modify the data step to only include the data relevant to that subject and period - you also need to move the WHERE data set option outside.
%MACRO AUC(dataset=, baseline=, subject=, period=, output=);
proc sql noprint;
select mean(yValue) format=6.2 into :baseY
from &dataset
where subject="&subject." and period="&period.";
quit;
DATA &output;
SET &dataset;
where subject="&subject." and period="&period." and Xtime GE 0;
....
3. Create a list of the individual subject/periods combination. No idea where baseline is created here, that's up to you to sort out.
*create list of baseline, subject and period to call the macro;
PROC SQL;
create table macro_call as
SELECT distinct 2 as baseline, subject, period
from have;
QUIT;
4. Call the macro once for each line in the data set and create an output dataset of the form: OUTPUT_SUBJECTID_PERIOD
*execute the macro for each line;
data demo;
set macro_call;
str = catt('%AUC(dataset=Have', ', baseline=', baseline, ', subject = ', subject, ', period= ', period, ', output= OUT_', catx('_', subject, period), ');');
call execute(str);
run;
5. Combine your output datasets into one data set.
data combined_out;
set output_: ;
run;
As someone else mentioned you should really understand the code but this gets you around it for now. I have no idea if this code is correct to calculate the AUC.
I'm also assuming that you only need the last line for each data set not the full one, but also leaving that up to you.
@DrSolverson wrote:
Hello,
I'm attempting to adapt a macro to calculate 3 different AUCs by subject and treatment period.
Here is a link to the original macro:
https://www.lexjansen.com/wuss/2004/posters/c_post_the_sas_calculations_.pdf
My issue is that I have 36 subjects and 4 treatment periods, and I am unsure how to modify the code to reflect two important details:
1. apply the baseline measurement from the SQL step to the appropriate subject and treatment period.
2. calculate SumTrapezoid so that it will start over when calculating a new subject and treatment period, instead of summing the entire trapezoid row.
The macro has the option to calculate the data three different (and very useful) ways. I'm guessing a few key lines could make this incorporate my study design (I just can't figure it out!). Any advice is greatly appreciated!
-Patrick
Subject Period Xtime Yvalue
5901 P1 -15 110.5
5901 P1 0 113.6
5901 P1 30 195.5
5901 P1 60 234.9
5901 P1 90 235.2
5901 P1 120 200.1
5901 P1 150 134.5
5901 P1 180 110.2
5901 P2 -15 115.1
5901 P2 0 115.6
5901 P2 30 201.1
5901 P2 60 262.5
5901 P2 90 227.6
5901 P2 120 214.4
5901 P2 150 191.7
5901 P2 180 142.6
5901 P3 -15 117.2
5901 P3 0 115.9
5901 P3 30 191.8
5901 P3 60 265.5
5901 P3 90 261.6
5901 P3 120 192.4
5901 P3 150 159.7
5901 P3 180 127.0
5902 P1 -15 92.6
5902 P1 0 95.1
5902 P1 30 140.8
5902 P1 60 154.0
5902 P1 90 121.9
5902 P1 120 108.3
5902 P1 150 84.2
5902 P1 180 94.3
5902 P2 -15 100.5
5902 P2 0 99.6
5902 P2 30 143.4
5902 P2 60 151.0
5902 P2 90 137.5
5902 P2 120 128.2
5902 P2 150 95.7
5902 P2 180 92.8
5902 P3 -15 98.3
5902 P3 0 96.7
5902 P3 30 156.0
5902 P3 60 196.6
5902 P3 90 190.3
5902 P3 120 172.8
5902 P3 150 136.9
PROC SQL;
SELECT subject, period, MEAN(Yvalue) FORMAT=6.2 LABEL='Avg Yvalue' INTO : BaseY FROM
Have WHERE Xtime <= 0
group by subject, period;
QUIT;
%MACRO AUC(baseline, dataset, output);
DATA &output;
SET &dataset (WHERE=(Xtime GE 0));
RETAIN Basevalue;
IF &baseline = 0 THEN Basevalue = 0.0;
* &BaseY shown in the following statement is the macro variable defined in any one of the above SQL
procedures;
IF (&baseline = 1 OR &baseline = 2) AND _N_ = 1 THEN Basevalue =
&BaseY;
Yvalue = Yvalue - Basevalue;
DROP LagTime LagValue;
LagTime = LAG(Xtime);
LagValue = LAG(Yvalue);
IF Xtime = 0 THEN DO;
LagTime = 0;
LagValue = 0;
END;
IF &baseline = 2 AND Yvalue > 0 AND LagValue <= 0.0 THEN DO;
* Connecting line with positive slope, only the area of right triangle (above baseline) is counted.;
DROP Ratio;
Ratio = Yvalue / (ABS(LagValue)+Yvalue);
Trapezoid = Ratio*(Xtime-LagTime)*(Yvalue+0.00)/2;
END;
ELSE IF &baseline = 2 AND Yvalue < 0 AND LagValue >= 0.0 THEN DO;
* Connecting line with negative slope, only the area of left triangle (above baseline) is counted.;
DROP Ratio;
Ratio = LagValue / (LagValue+ABS(Yvalue));
Trapezoid = Ratio*(Xtime-LagTime)*(0.00+LagValue)/2;
END;
ELSE IF &baseline = 2 AND Yvalue < 0 AND LagValue < 0 THEN Trapezoid =
0.0;
* Negative trapezoidal area is not counted.;
ELSE Trapezoid = (Xtime-LagTime)*(Yvalue+LagValue)/2;
* The rest of all positive trapezoidal areas are counted.;
SumTrapezoid + Trapezoid;
FORMAT Trapezoid SumTrapezoid 8.3;
RUN;
%MEND AUC;
%AUC(2, have, want);
Click image to register for webinar
