enter value from one dataset into another

[franph]

Hi

I would like help to code this please ....

currently I have a data step that is coded:

data daily1;

set daily;

retain accruingbal 3451.76;

accruingbal+amount;

run;

.. but it means I manually have to enter the amount each time I run it

how can I write it to get the amount from another dataset?

data daily1;

set daily;

retain accruingbal = value called Openingbal in dataset called Opening;

accruingbal+amount;

run;

thanks for your help 🙂

[Jagadishkatam]

data daily1;

merge daily x;

by byvariable;

retain accruingbal;

accruingbal+amount;

run;

Please try this untested code.

[dkb]

Presumably you are confident that there is only one observation in the "Opening" dataset?  You can read it the first time through the data step but not thereafter:

data daily1;

drop openingbal;

if _N_ = 1 then do;

  set opening(keep = openingbal);

  accruingbal = openingbal;

end;

set daily;

accruingbal+amount;

run;

[Kurt_Bremser]

You can use a macro variable and sql to automate this:

proc sql noprint;

select openingbal into :init_value from opening;

quit;

* make sure that opening has only one observation, or use a where condition to only get the observation you want;

data daily1;

set daily;

retain accruingbal &init_value;

accruingbal+amount;

run;

Edit: adapted my original posting to your variable/dataset names.