apply format to proc print without var

[csetzkorn]

This works fine:

proc format; 
 value Bla 
    low -< -1.0 = "red" 
    -1 -< 0 = "green"
	0 - high = "white"; 
run;

proc print data=Temp NOOBS; 
	var X Y Z
	/style(data) = [background=Bla.];	 
run;

I am in a situation where my vars are dynamic so I cannot use the /style option. Is there a way to apply the above format to all numeric values in the table to be printed?

[RW9]

Something like:

proc print data=temp noobs;
  var x y z;
  format _numeric_ bla.;
run;

[csetzkorn]

Thanks. Firstly I cannot use var. Secondly (tried this) but it does not change the background color but prints the format values.

[RW9 · Accepted solution]

You can always use var, even if its a matter of doing:

proc sql;
  select name into :vlist separated by " " 
  from sashelp.vcolumn 
  where libname="WORK" and memname="TEMP";
quit;

proc print data=temp;
  var &vlist.;
run;

"Can't" is not in programming.

As for the issue, the key is to use the _numeric_ SAS command, which means all numeric variables:

proc print data=temp;
  var _numeric_ / style(data)=[background=bla.];
run;

[csetzkorn]

wow this is exactly what I needed (-: