Passing values from table to macro variable.

[pr1]

I have this import statement:

PROC IMPORT DATAFILE = 'C:\ Data Files\AAAAAA\DN txns BBBBBB Test.xlsx'

                DBMS=XLSX

                OUT = WORK.AP_XXXXXXXX;

                SHEET = 'Sheet1';

I have some 50 of such import statements in my code. 

In the above statement AAAAAA, BBBBBB, XXXXXXXX comes from one SAS table with three columns which contains these values.  

Is it possible to read these fields from SAS table and pass the value to the above statement and make it execute 50 times? 

Thanks.

PR

[LinusH]

CALL EXECUTE();

[Tom · Accepted solution]

Yes.

CALL EXECUTE() is one way.

You can also generate the code to a file as text output using the PUT statement and then %INCLUDE the generated code.

Let's assume you have table named HAVE with variables A, B and X containing the strings above.

data have ;

  input (A B X) ($);

cards;

AAAAA BBBBB XXXXX

;;;;

data _null_;

  set have ;

  cmd =

   catx(';'

       ,catx(' ','PROC IMPORT DATAFILE ='

                ,quote(cats('C:\Data Files\'

                           ,A

                           ,catx(' ','\DN txns',B,'Test.xlsx')

                           ))

                ,'DBMS=XLSX'

                ,cats('OUT = WORK.AP_',x)

            )

       ,"SHEET = 'Sheet1'"

       ,'run;'

       )

  ;

  putlog cmd= ;

  call execute(cats(cmd));

run;

[Tom]

Writing to a file can make the syntax simpler.  Especially if you make variable names that match the option names so that you can use the = operator in the PUT statement.

It also has the advantage that you can create the file and look at it to verify the syntax before executing it.

filename code temp;

data _null_;

  set have ;

  datafile = cats('C:\Data Files\',A,catx(' ','\DN txns',B,'Test.xlsx'));

  out = cats('WORK.AP_',x);

  file code ;

  put 'PROC IMPORT '  DATAFILE = :$quote.

      'DBMS=XLSX ' OUT= ';'

    / "SHEET = 'Sheet1';"

    / 'run;'

  ;

run;

%inc code / source2 ;

[pr1]

This works!!  THANKS!!!