I don't see how order matters.
And you can use SASHELP.VCOLUMNS to simplify your query.
Here's a macro I wrote to solve the problem a while back but you can easily remove the macro portion if you don't need it:
SAS_compare_dataset_variables · GitHub
%macro compare_data(base=, compare=);
proc sql noprint;
create table base_in as
select name
from sashelp.vcolumn
where libname=upper(scan("&base", 1, "."))
and memname=upper(scan("&base", 2, "."))
order by varnum;
quit;
proc sql noprint;
create table compare_in as
select name
from sashelp.vcolumn
where libname=upper(scan("&compare", 1, "."))
and memname=upper(scan("&compare", 2, "."))
order by varnum;
quit;
proc sql;
create table comparison as
select a.name as base_var, b.name as compare_var,
case when missing(a.name) then catx("-", "Comparison dataset has extra variable", b.name)
when missing(b.name) then catx("-", "Comparison dataset is missing variable", a.name)
when a.name=b.name then "Variable in both datasets"
else "CHECKME"
end as comparison
from base_in as a
full join compare_in as b
on a.name=b.name;
quit;
/* data _null_; */
/* set comparison; */
/* if comparison not eq "Variable in both datasets" */
/* then put "ERROR:" comparison; */
/* run; */
%mend;
/*example of calling macro*/
data class;
set sashelp.class;
bmi=(weight/(height**2))*703;
run;
data class2;
set sashelp.class;
weight_kgs=weight*0.453592;
height_cm=height*2.54;
run;
%compare_data(base=work.class2, compare=work.class);
