How do I convert a format into a string value?

[Tpham]

So this is what I have right now

proc format;
  value namefmt 1="Experiment" 2="Control";
run;

data have;
input name  count;
datalines;
1 16
2 8
;
run;

data have;
set have;
format name namefmt.;
run;

data want;
set have;
wantvar=name||" (N="||count||")";
run;

So in my want database, my wantvar is showing up as "1 (N=          16)", where I want it to actually show up as "Experiment (N=16)".

How can I get it to show the formatted value and not the actual value without creating a new variable?

[stat_sas]

data want;

set have;

wantvar=put(name,namefmt.)||" (N="||count||")";

run;

[FriedEgg]

proc format;

  value namefmt 1="Experiment" 2="Control";

run;

data have;

input name count;

want=catx(' ', put(name, namefmt.), cats('(N=', count, ')'));

datalines;

1 16

2 8

;

proc print;

run;

[ballardw · Accepted solution]

To remove the space before the number on way:

wantvar=put(name,namefmt.)||" (N="||strip(count)||")";

[user24feb]

Try: Wantvar=Catt(Put(Name,namefmt.),' N=(',Count,')'); * I guess the others were much quicker though ..;

[Steelers_In_DC]

Tpham, you will want to use a put function:

proc format;

value $namefmt 1="Experiment" 2="Control";

run;

data have;

Input name $  count;

datalines;

1 16

2 8

;

run;

data want;

format name $ namefmt.;

set have;

wantvar= catx('',put(name,namefmt.),'(N=',count,')');

run;