BookmarkSubscribeRSS Feed
Yennie
Calcite | Level 5
hi people,

I know SAS can do this through Edit mode by adding rows to the dataset manually. However, I am writting an automated script so I need to write out the sas code to add two extra empty rows to my dataset.

Hoping someone can give me some directions!

Cheers,
Yennie
7 REPLIES 7
sbb
Lapis Lazuli | Level 10 sbb
Lapis Lazuli | Level 10
Empty rows -not sure why but you can assign a MISSING or BLANK value to all variables in the dataset and issue the OUTPUT; command. Possibly you might want to explain why you need this condition?

Scott Barry
SBBWorks, Inc.
Cynthia_sas
Diamond | Level 26
Hi:
You will want to test for the end of the input file so that you only write out your two empty observations at the end. The END= option allows you to perform this test, as shown below.

cynthia
[pre]
data newclass;
** create variable to signal end of input file;
set sashelp.class end=nomore;

** output regular observations;
output;

** test for end of file. At end, NOMORE = 1;
if nomore then do;
** set variables to missing;
name = ' ';
sex = ' ';
height = .;
age = .;
weight = .;
** output 2 "empty" observations;
output;
output;
end;
run;

ods listing;
proc print data=newclass;
title '2 "empty" observations at end of file';
run;
[/pre]
Yennie
Calcite | Level 5
Hi Cynthia,

That really helps lots!

Many many thanks!! 🙂 🙂

Cheers,
Yennie
Stewartli
Obsidian | Level 7

Hi Cynthia, 

I use SAS Enterprise Miner. SAS Enterprise Miner automatically added 2 empty rows to my dataset after imported dataset. I am not sure why it did that. Is there any method I can remove those rows? Thank you for your help. 

Regards, 

Stewart

 

darrylovia
Quartz | Level 8
You could also use PROC SQL to do it



proc sql;

create table shoes as
select *
from sashelp.shoes;

insert into work.shoes
set Region="";
insert into work.shoes
set Region="";
quit;

In the SET clause just pick any variable that is in your data set

D
s_lassen
Meteorite | Level 14

The fastest and easiest way to do it is probably to modify the dataset in place:

data x;
  if 0 then modify x; /* modify, but do not read any rows */
  output;
  output;
stop; run;
Stewartli
Obsidian | Level 7
Thank you Iassen. Appreciate it.

hackathon24-white-horiz.png

The 2025 SAS Hackathon Kicks Off on June 11!

Watch the live Hackathon Kickoff to get all the essential information about the SAS Hackathon—including how to join, how to participate, and expert tips for success.

YouTube LinkedIn

What is Bayesian Analysis?

Learn the difference between classical and Bayesian statistical approaches and see a few PROC examples to perform Bayesian analysis in this video.

Find more tutorials on the SAS Users YouTube channel.

SAS Training: Just a Click Away

 Ready to level-up your skills? Choose your own adventure.

Browse our catalog!

Discussion stats
  • 7 replies
  • 16099 views
  • 1 like
  • 6 in conversation