How can I determine if shipment date was done on shipment date?

[BETO]

Hi I have a data set that looks like this

ID        sunship mon ship tue ship wed ship Thursday ship  fri ship sat ship.   Date ship

7918.     0.           1.               0.          1.                      0.           0.          0.         05/01/13

1234.     1.           0.               0.           0.                      1.            0.         0.          05/03/13

the ship is date of week there is a shipment   Date ship is actual day the ship happen. What I would like is to determine if was ship on correct date  for example 05/01/13 was. Correct because it was done on a Wednesday . the 05/03/13 incorrect on wrong day it was on a Friday ....

Thank you again for your assistance

[DBailey]

how about something like this:

proc sql;

create table work.incorrect_shipment_dates as

select

     *

from

     work.have

where

     not case weekday(date_ship)

          when 1 then sunship

          when 2 then monship

          ..

          when 7 then Satship

end;

quit;

[Reeza]

The weekday function in SAS will give you the weekday in 1 to 7. 

Then you can check if your shipped day is 1 on that day.

You have two 1s for the 1st one example so not sure how you want to handle that.

data want;

set have;

array ship(7) sun_ship-sat_ship;

weekday_shipped=weekday(date_ship);

if ship(weekday_shipped)=1 then correct_ship=1;

else correct_ship=0;

run;

[PGStats · Accepted solution]

Or simply

data want;

set have;

array ship(7) sun_ship -- sat_ship;

correct_ship = ship(weekday(date_ship));

run;

PG

[DBailey]

better.

[JBerry]

very nice

[Scott_Mitchell]

I love this solution.

Great work.

[slchen]

data have;

input id ship_sun ship_mon  ship_tue  ship_wed  ship_thu  ship_fri  ship_sat  ship_date mmddyy10.;

format ship_date date9.;

cards;

7918     0   0   0   1  0  1  0  05/01/13

1234     1   0   0   0  1  0  0  05/03/13

;

run;

data want(drop=day);

  set have;

  array weekdays ship_sun--ship_sat;

      do over weekdays;

            if weekdays=1 then do;

                day=scan(vname(weekdays),-1,'_');

                  if lowcase(put(ship_date,weekdate3.))=day then yes_ship=day;

              end;

         end;

run;

proc print;

run;