Name city county
Ann A 1
Betty B 2
Carol A 1
Dave B 2
Ethel A 2
I want to output a file that groups by county and then city and write those obs on one line with the names listed that are associated with that city and county, like so:
Name city county
Ann, Carol A 1
Betty, Dave B 2
Ethel A 2
data have;
input Name :$ city :$ county;
cards;
Ann A 1
Betty B 2
Carol A 1
Dave B 2
Ethel A 2
;
proc sort;
by county city name;
data want;
retain new;
length new $50;
set have;
by county city;
new=catx(',',new,name);
if last.city then do;
output;
call missing (new);
end;
proc print;run;
Or using DOW:
data have;
infile cards;
input (Name city county) (:$);
cards;
Ann A 1
Betty B 2
Carol A 1
Dave B 2
Ethel A 2
;
proc sort data=have;
by county city;
run;
data want;
length group $40;
do until (last.city);
set have;
by county city;
group=catx(',',group,name);
end;
run;
proc print;run;
Haikuo
Don't miss out on SAS Innovate - Register now for the FREE Livestream!
Can't make it to Vegas? No problem! Watch our general sessions LIVE or on-demand starting April 17th. Hear from SAS execs, best-selling author Adam Grant, Hot Ones host Sean Evans, top tech journalist Kara Swisher, AI expert Cassie Kozyrkov, and the mind-blowing dance crew iLuminate! Plus, get access to over 20 breakout sessions.
Learn the difference between classical and Bayesian statistical approaches and see a few PROC examples to perform Bayesian analysis in this video.
Find more tutorials on the SAS Users YouTube channel.