Getting value from first column first row without knowing the variable name?

[jerry898969]

I need to get the value of the first variable first row of a data set without knowing the variable name. 

The reason for this is I have to create a macro that will loop through many datasets and look at the first variable first row's value.  Each data set has a different name for the first variable.

Any help would be appreciated.

Thank you

[NickR]

proc sql noprint;

          select name into :firstvar from dictionary.columns where libname='SASHELP' and memname='CLASS'

          and varnum=1;

quit;

proc print data=sashelp.class (obs=1);

          var &firstvar;

run;

[data_null__]

A slight variation on NickR's method.  This gets a list of MEMNAMEs and variables NAMEs you can create a data table to run a macro or other code generator.

proc sql;

   select name, memname

      from dictionary.columns

      where libname eq 'SASHELP' and memtype in('DATA') and varnum eq 1

      ;

   quit;

   run;

[Ksharp]

Hi. I found this can be achieve by proc sql. It is very interesting, but there a Warning message

in log , If you do not care about it.

proc sql noprint;
 select *
  into : first_value1 
   from sashelp.class;

 select *
  into : first_value2
   from sashelp.air;

quit;
%put &first_value1 &first_value2;






proc sql noprint;
 select *
  into : first_value1 
   from sashelp.class;

 select *
  into : first_value2
   from sashelp.air;

quit;
%put &first_value1 &first_value2;

Ksharp

[Howles]

Here's a way using the DATA step:

data _null_ ;

set sashelp.shoes ;

length __name $32 ;

call vnext(__name);

r1c1 = vvalue(__name) ;

put r1c1= ;

stop ;

run ;

jerry898969 wrote:
I need to get the value of the first variable first row of a data set without knowing the variable name.  
The reason for this is I have to create a macro that will loop through many datasets and look at the first variable first row's value.  Each data set has a different name for the first variable.
Any help would be appreciated.
Thank you

[Ksharp]

H. Howles

Maybe it should be vvaluex()?

Ksharp