Change case of variable name

[aerbe]

Is there a way to change the letters in a variable name from uppercase to lowercase?

Thank you!

[art297]

Never did it!  However, rename in a datastep should work (e.g., UNTESTED:)

data sashelp.class;

  set sashelp.class(rename=(name=NAME));

run;

I can't test it at the moment, but I would think that the lowcase, upcase and propcase functions could be used as well.  e.g.,

data sashelp.class;

  set sashelp.class(rename=(name=upcase(NAME)));

run;

[Howles]

I think you need %SYSFUNC, as in

data have ;

myvar = 0 ;

run ;

data want ;

set have(rename=(myvar=%sysfunc(upcase(myvar))));

put _all_ ;

run;

[RICARDOIS]

%let per = %sysfunc(lowcase(&period));
%put &per;
feb2017

With this I can now read/email sas datasets. filename_@per.sas7bdat files in UNIX/LINUX !!! Yey!!!

[BobD · Accepted solution]

Use the RENAME statement in PROC DATASETS (avoiding recreating the data set):

data have;
  myvar = 0;
run;

data _null_;
  set have;
  put _all_;
run;

proc datasets lib=work nolist;
  modify have;
     rename myvar=MYVAR;
run;
quit;

data _null_;
  set have;
  put _all_;
run;

[aerbe]

Thanks Bob, this worked well!

[Linlin]

How about:

data have;

input (AA  BB  cc) ($);

cards;

qw er ty

cd rt ty

;

proc print;run;

proc sql noprint;

select catx('=',name,lowcase(name)) into : names separated by ' '

  from dictionary.columns

    where libname='WORK' and memname='HAVE';

quit;

proc datasets lib=work nolist;

modify have;

rename &names;

run;

quit;

proc print;run;

Linlin