Adding leading zeroes to character variable

[GKati]

Dear All, 

I have a large dataset with diagnosis codes that are up to four digits. I need to make them more uniform by adding zeros preceding the first digit (letter) to make them 4 digits but in a character format. 

I've tried this but I end up with all zeros.

data diagnosis;

input diagnosis;

datalines;

094

16

E4

;

run;

data diagnosis;

set diagnosis;

diagnose=translate(right(diagnosis),'0',' ');

;

run;

My desired output would be this:

0094

0016

00E4

[Kurt_Bremser · Accepted solution]

First of all, your first data step won't really work, as you try to create a numeric variable, so add a dollar sign:

data diagnosis;
input diagnosis $;
datalines;
094
16
E4
;
run;

Then try this:

data diagnosis;
set diagnosis;
length newdiag $4;
newdiag = '0000';
substr(newdiag,5-length(diagnosis)) = diagnosis;
drop diagnosis;
rename newdiag=diagnosis;
run;

[GKati]

Perfect. This works well. 

[RW9]

data want;
  var="E4";
  want=cats(repeat('0',3-lengthn(var)),var);
run;

[Ksharp]

data diagnosis;
input diagnosis $;
datalines;
094
16
E4
;
run;
data diagnosis;
set diagnosis;
length newdiag $4;
newdiag = diagnosis;
newdiag= translate(right(newdiag),'0',' ');
run;