Contrast Statement in Proc Logistic.

[Rucstat_huadli]

In a logistic model, the explanatory variable treatment has four levels.I want to test the first versus the fourth level of treatment, we usually use this contrast statement below

contrast '1 vs 4' treatment 1 0 0 -1;

but,I read the SAS help about The LOGISTIC Procedure contrast statement,they use

contrast '1 vs 4' treatment 2 1 1;

Both have different results,Why?

[Olivier]

I guess it depends on the way your variables are coded : check the PARAM option in the CLASS statement.
If you typed CLASS treatment / PARAM = GLM ; then your coefficients 1 0 0 -1 are correct. If you simply used CLASS treatement ; without options, or with PARAM=EFFECT, then the coefficients would be 2 1 1 as the help says.

Both lead to the same results :
[pre]
ODS SELECT contrastTest (PERSIST) ;
PROC LOGISTIC DATA = sashelp.class ;
WHERE age IN (12,13,14,15) ;
CLASS age ;
MODEL sex = age ;
CONTRAST "test 12 vs 15" age 2 1 1 ;
RUN ;
PROC LOGISTIC DATA = sashelp.class ;
WHERE age IN (12,13,14,15) ;
CLASS age / PARAM = GLM ;
MODEL sex = age ;
CONTRAST "test 12 vs 15" age 1 0 0 -1 ;
RUN ;
ODS SELECT ALL ;
[/pre]

[Rucstat_huadli]

Thanks!