How to create header in txt file export that includes count of rows/observations

[Paul628]

Hello all,

I have the following code and my goal is to have a txt. export with a header that includes the number of rows/obs from my dataset.

DATA have;
SET have END=EOF;
file "filepath.txt" dlm='|';

put (_all_)(~);
IF EOF then 
	do;
		put 'Number of Rows:'_n_:Z7.;		
	end;
run;

As it is now, the only way I could get _n_ to include a count of rows/obs was to put it at the end. When I used:

if _n_>0 then

do;

put 'Number of Rows:'_n_:z7.;

end;

run;

then the header was at the top of the file, but _n_ = 1.

Any help is much appreciated.

Thank you.

[TomKari · Accepted solution]

proc sql noprint;
	select nobs into :rowcount
		from dictionary.tables
			where upcase(libname) = "SASHELP" and upcase(memname) = "CLASS";
quit;

data _null_;
	SET sashelp.class;
	file "!USERPROFILE\Desktop\want.txt" dlm='|';

	if _n_ = 1 then
		put "Number of Rows: &rowcount.";
	put (_all_)(~);
run;

[Paul628]

Worked like a charm!

Thank you,

Paul

[svh]

One way--maybe not the best way--is to use CALL SYMPUTX in a prior step. This way, you can store the total number of observations in a macro variable that you call when you export the text file. In this example, the number of observations is printed above the list of values. I'm not sure if this is exactly what you're looking for, but it may help. 

data have;
input x @@;
datalines;
1 2 3 4 5 6 7 8 9 0 
;
run;
proc print;
run;

data _null_;
   set have;
   total = _n_ ;
   call symputx("macro_total", total);
   run; 
data _null_;
	set have;
	file "c\file.txt";
	if _n_ = 1 then do;
	   put "&macro_total";
	   end;
    put x;
	run;