Sense you say all of these sets are in a specific subfolder then I would expect then all to be in the same SAS library.
You get call of the datasets and how many observations they have with this code:
data want;
set sashelp.vtable;
where libname='WORK';
keep libname memname nobs;
run;
/* or */
proc sql;
create table want as
select libname,memname, nobs
from dictionary.tables
where libname='WORK'
;
quit;
Replace WORK with the name of your library. The name is stored in the SAS metadata in uppercase so make sure to use upper case spelling.
Then to create the final wanted data set:
Proc sql;
create table final as
select a.libname, a.memname, a.nobs
,case upcase(b.name)
when 'YOURVARIABLE' then 'Yes'
else 'No'
end as YOURVARIABLE
from want as a
left join
(select * from dictionary.columns
where upcase(name)='YOURVARIABLE' ) as b
on a.libname=b.libname
and a.memname=b.memname
;
quit;
The Procedure SQL allows use of SQL statements to join data sets in many manners (LOTS of books out there). In this case the previous data set contains the bits you had, library, memname (data set name) and nobs (number of observations). The SAS metadata view holding all the information about variable properties such as name, which can be stored in mixed case so I force an upper case comparison, type, label, format, length and other bits then is used to select when the variable name is the one you want, using "YOURVARIABLENAME" above, only in that library using a WHERE clause. The "as A" and "as B" after the data set name or the query (select * from dictionary.columns ... ) are alias so you can refer to the variables with the prefix a.<variable name> or b<variable name>. The Left Join will select all the records from the A set, the ON clause provides conditions on matching, the library and member name this time. The CASE clause examines the contributing value of the B.Name to the desired value. If it is there then we assign a value of 'Yes' as requested, else assign "No" to a column with the name of the variable you asked about.
Personally instead of 'Yes' and 'No' I would use numeric 1/0 for Yes/No with code like this:
Proc sql;
create table final as
select a.libname, a.memname, a.nobs
,( upcase(b.name) = 'YOURVARIABLE') as YOURVARIABLE
from want as a
left join
(select * from dictionary.columns
where upcase(name)='YOURVARIABLE' ) as b
on a.libname=b.libname
and a.memname=b.memname
;
quit;
because there are several things that are easier to report when you only want to count/sum/calculate with the "yes" values that don't work quite as nice with character values.
There are lots of metadata available in SAS. Knowing it is there is the first thing. Then learning tools to use it.
This would be how to check on TWO variables:
Proc sql;
create table final as
select a.libname, a.memname, a.nobs
,( upcase(b.name) = 'YOURVARIABLE') as YOURVARIABLE
,( upcase(b.name) = 'OTHERVAR') as OTHERVAR
from want as a
left join
(select * from dictionary.columns
where upcase(name)in ('YOURVARIABLE' 'OTHERVAR') ) as b
on a.libname=b.libname
and a.memname=b.memname
;
quit;
Another way would be to create a data set with the names of the variables and do a join on the dictionary.columns to get just the sets that have those variables and then do a similar join with the data of members and obs.
