@Jamie_H
This code appears to be a utility macro which you are allowed to modify as you wish.
Looking into the actual code the one bit which won't work with option NOXCMD is the pipe using DIR for the directory listing.
filename filelist pipe %unquote(%str(%'dir "&PATHIN\*" /b%'));
data _null_;
infile filelist truncover end=finalObs;
length fname $50;
retain i 1; /* Have to initialize counter */
input fname; /* Post code file name from pipe */
/*--- Import only CSV files and ignore any others. */
if index(fname, '.csv ') then do;
/*--- Put name in numbered FNAMEi macro
var and increment file counter. */
call symputx('FNAME' || trim(left(put(i,8.))), trim(fname));
i+1;
end;
/*--- If last file, put final count into FILETOTAL macro variable. */
if finalObs then
call symput('FILETOTAL', trim(left(put(i-1,8.))));
run;
You can also get such a directory listing using SAS code only.
To make things work for you change the above code bit in the macro with below code which should return the exactly same result.
data _null_;
length fname $50;
retain cnt 0; /* Have to initialize counter */
/* Assigns a fileref to the directory and opens the directory */
_rc=filename("filrf","&PATHIN");
_did=dopen("filrf");
/* Make sure directory can be opened */
if _did eq 0 then
do;
put "Directory &pathin cannot be opened or does not exist";
put "aborting job ... aborting job ... aborting job...";
abort abend;
stop;
end;
/* Loops through entire directory */
do _i = 1 to dnum(_did);
/* Retrieve name of each file */
fname=dread(_did,_i);
/*--- Import only CSV files and ignore any others. */
if index(fname, '.csv ') then
do;
/*--- Put name in numbered FNAMEi macro
var and increment file counter. */
cnt+1;
call symputx('FNAME' || put(cnt,8. -l), trim(fname));
output;
end;
end;
/*--- If last file, put final count into FILETOTAL macro variable. */
call symputx('FILETOTAL', put(cnt,8. -l));
/* Closes the directory and clear the fileref */
_rc=dclose(_did);
_rc=filename("filrf");
run;
