Bonjour,
Vous pouvez examiner comment une MERGE (FUSION) fonctionne à côté de courir ce code. Examiner alors soigneusement le rendement dans les 4 dossiers différents créés par la MERGE (FUSION). Vous devez décider quelle logique donne le dossier qui est identique au dossier que vous voulez.
[pre]
data toto;
input cleName$ grp $ other $;
return;
datalines;
dorothy aaa blue
tinman aaa silver
scarecrow bbb yellow
lion ccc yellow
wizard ccc green
glinda ddd pink
;
run;
data tutu;
input cleName $ place $;
return;
datalines;
dorothy kansas
tinman forest
scarecrow field
glinda bubble
wizard oz
witch house
;
run;
proc sort data=toto;
by cleName;
run;
proc sort data=tutu;
by cleName;
run;
data BOTH TOTO_ONLY TUTU_ONLY ALL;
merge toto(in=a)
tutu(in=b);
by cleName;
totoflag = a;
tutuflag = b;
if a=1 and b=1 then do;
song = 'Over the Rainbow ';
output BOTH;
end;
if a=0 and b=1 then do;
song = 'Ding Dong ';
output TUTU_ONLY;
end;
if a=1 and b=0 then do;
song = 'King of the Forest ';
output TOTO_ONLY;
end;
output ALL;
run;
proc print data=BOTH;
title 'IN TOTO and IN TUTU files';
run;
proc print data=TOTO_ONLY;
title 'IN TOTO file only';
run;
proc print data=TUTU_ONLY;
title 'IN TUTU file only';
run;
proc print data=ALL;
title 'ALL OBS WITH FLAGS';
run;
[/pre]
Pour plus d'aide, particulièrement avec SAS Enterprise Guide, vous devriez entrer en contact avec SAS Technical Support.
Le support téléphonique est accessible au 01 60 62 12 12
du lundi au vendredi de 9h00 à 17h30 (17h00 le vendredi).
Pour tout envoi de questions et problèmes: support@sas.com
Pour plus d'aide, particulièrement avec SAS Enterprise Guide, vous devez entrer en contact avec SAS Technical Support:
http://support.sas.com/techsup/contact/index.html
http://www.sas.com/offices/europe/france/services/support/index.html
cynthia