BookmarkSubscribeRSS Feed
🔒 This topic is solved and locked. Need further help from the community? Please sign in and ask a new question.
LAtwood
Calcite | Level 5

I am trying to skip a line after a "break after" statement using proc report.  This is a stored process that will run on the SAS Stored Process Server.  I would like to skip a line after summing up totals by prob_num.  Here is my code:

options orientation=landscape center number;

ods pdf file=_WEBOUT notoc;

proc report data=WORK.SORTSortedQUERY_FOR_PAY_MONTHLY_;

title justify=left "Monthly Bonus Calculation"

justify=center "&bonus_month - &bonus_yr"

justify=right "HP14";

footnote "Generated by the SAS System on %TRIM(%QSYSFUNC(DATE(),MMDDYY8.)) at %TRIM(%SYSFUNC(TIME(),TIMEAMPM12.))";

column prob_num cc pos clock_num reg_hrs1 reg_amt1 ot_hrs1 ot_amt1 sun_hrs1 sun_amt1 worked_holiday_hrs1 worked_holiday_amt1

unworked_holiday_hrs1 unworked_holiday_amt1 tot_hrs tot_amt;

define prob_num / group 'Prob' ;

define cc / display 'CC' ;

define pos / display 'Pos' ;

define clock_num / group 'Clock No';

define reg_hrs1 / sum 'Reg Hrs' ;

define reg_amt1 / sum 'Reg Amt' ;

define ot_hrs1 / sum 'OT Hrs' ;

define ot_amt1 / sum 'OT Amt' ;

define sun_hrs1 / sum 'Sun Hrs' ;

define sun_amt1 / sum 'Sun Amt' ;

define worked_holiday_hrs1 / sum 'Worked Hol Hrs' ;

define worked_holiday_amt1 / sum 'Worked Hol Amt' ;

define unworked_holiday_hrs1 / sum 'Unworked Hol Hrs' ;

define unworked_holiday_amt1 / sum 'Unworked Hol Amt' ;

define tot_hrs / sum 'Tot Hrs' ;

define tot_amt / sum 'Tot Amt' ;

break after clock_num / summarize style=[font_weight=bold] ;

break after prob_num / summarize style=[font_weight=bold] skip;

rbreak after / summarize style=[font_weight=bold] ;

run;

ods _all_ close;

I place the "skip" in the break after statement, but it does not skip a line.   Am I missing something?

Thanks!

1 ACCEPTED SOLUTION

Accepted Solutions
Cynthia_sas
SAS Super FREQ

Hi:

  There are many PROC REPORT options that are LISTING only options and SKIP on a BREAK statement is one of those options (as are HEADLINE, HEADSKIP, OL, UL, BOX, etc), per this Tech Support note:

http://support.sas.com/kb/2/549.html

As the note suggests, using a LINE statement is the way to have the equivalent of the SKIP happen in ODS destinations (non-LISTING destinations). For example:

compute after prob_num;

  line ' ';  /* quote space quote */

endcomp;

cynthia

Also, since this is a stored process, just remember that it is possible that clients like Web Report Studio or PowerPoint may not use/honor the options. Those two client applications, in particular, use SASReport XML and they do not use all the PROC REPORT features. This is just one of the Tech Support notes about an issue: http://support.sas.com/kb/19/950.html

added some stored process info

View solution in original post

2 REPLIES 2
Cynthia_sas
SAS Super FREQ

Hi:

  There are many PROC REPORT options that are LISTING only options and SKIP on a BREAK statement is one of those options (as are HEADLINE, HEADSKIP, OL, UL, BOX, etc), per this Tech Support note:

http://support.sas.com/kb/2/549.html

As the note suggests, using a LINE statement is the way to have the equivalent of the SKIP happen in ODS destinations (non-LISTING destinations). For example:

compute after prob_num;

  line ' ';  /* quote space quote */

endcomp;

cynthia

Also, since this is a stored process, just remember that it is possible that clients like Web Report Studio or PowerPoint may not use/honor the options. Those two client applications, in particular, use SASReport XML and they do not use all the PROC REPORT features. This is just one of the Tech Support notes about an issue: http://support.sas.com/kb/19/950.html

added some stored process info

LAtwood
Calcite | Level 5

Thanks Cynthia!

sas-innovate-2024.png

Join us for SAS Innovate April 16-19 at the Aria in Las Vegas. Bring the team and save big with our group pricing for a limited time only.

Pre-conference courses and tutorials are filling up fast and are always a sellout. Register today to reserve your seat.

 

Register now!

How to Concatenate Values

Learn how use the CAT functions in SAS to join values from multiple variables into a single value.

Find more tutorials on the SAS Users YouTube channel.

Click image to register for webinarClick image to register for webinar

Classroom Training Available!

Select SAS Training centers are offering in-person courses. View upcoming courses for:

View all other training opportunities.

Discussion stats
  • 2 replies
  • 2454 views
  • 0 likes
  • 2 in conversation