PROC DOCUMENT: How to delete all documents?

[WendyT]

Good morning!

I've been looking through the documentation, and can't figure out how to do deletes in the Document store without naming each item.

I'm processing several programs in batch, and trying to clean up in-between.

Thanks for your help!

WendyT.

[WendyT]

Folks-

I did figure out that I could get rid of the items using MEMTYPE in proc datasets, but am still interested in doing this from proc documents.

Thanks!

WendyT

PROC DATASETS LIB=WORK KILL MEMTYPE=(ITEMSTOR) ;

RUN ;

QUIT ;

[BrunoMueller · Accepted solution]

Hi Wendy

You are right you have to name all entries you want to delete. But you do not have to do it manually, with the help of some code this is done automatically, see below for an example

ods output Properties=_properties;

proc document;
  doc name=mydoc;
  list  / levels=all details follow order=insert ;
run;

quit;

proc sql number;
  select
    path
  into
    :pathList separated by ", "
  from
    _properties
  where
    type = "Dir"
    and countw(path, "\") = 1
  ;
quit;

%put NOTE: &=pathList;

proc document;
  doc name=mydoc;
  title "before delete";
  list  / levels=all details follow;
run;

  delete &pathList;
run;

  list  / levels=all details follow;
run;

quit;

[WendyT]

Bruno-

Thanks so much for the answer!

Wendy