Hi:
When I run the code below in SAS 9.1.3 on Windows to create an ODS PDF file, I get (the expected) 2 pages of output with 2 Tabulates on each page. I wonder whether the PIPE command to a printer file has some other behavior with ODS and STARTPAGE. Possibly this Tech Support note is relevant to your situation:
http://support.sas.com/kb/11/535.html
You might wish to contact Tech Support directly for more help on this issue.
cynthia
[pre]
options orientation=portrait nodate number;
ods pdf file='c:\temp\test_sp.pdf'
startpage=no;
proc tabulate data=sashelp.shoes;
title '1) Region Min Mean Max';
class region;
var sales;
table region all,
sales * (min mean max);
run;
ods pdf text='2) Product Min Mean Max';
proc tabulate data=sashelp.shoes;
title '2) Product Min Mean Max';
class product;
var sales;
table product all,
sales * (min mean max);
run;
ods pdf startpage=now;
proc tabulate data=sashelp.shoes;
title '3) Region sum PCTSUM';
class region;
var sales;
table region all,
sales * (sum pctsum);
run;
ods pdf startpage=no;
ods pdf text= '4) Product sum PCTSUM';
proc tabulate data=sashelp.shoes;
title '4) Product sum PCTSUM';
class product;
var sales;
table product all,
sales * (sum pctsum);
run;
ods pdf close;
[/pre]