Sorry:
I cross-posted with you. I'm not sure what you're trying to achieve with your PROC TEMPLATE and PROC REPORT code.
When you use the REPLACE statement in SAS 9.1.3, you must RESPECIFY all the style elements that you want to keep, as outlined here in the documentation:
http://support.sas.com/rnd/base/early-access/odsdoc2/sashtml/tw5195/z1072349.htm
where it says:
If you use the REPLACE statement to create a style element in the new style definition, all style elements that inherit from that element inherit the definition that is in the new style definition. If you want to keep any attributes that are specified in the definition that is in the parent, you must respecify them in the definition that you create in the child style definition.
Usually, with a template such as yours, I would expect to see more style attributes specified for both TABLE and HEADER style elements. However, since you're using PROC REPORT and are using STYLE attributes in the REPORT syntax, I'm not sure why you're even using a custom TEMPLATE at all.
In your PROC REPORT code, you have some options, like SPACING= and FLOW and LS and WRAP .... which will NOT be used by ODS PDF at all. These are "LISTING" destination options -- meant to be used in a destination, such as the LISTING window or OUTPUT window, where every character represents 1 print position in a monospace font. Since ODS works with proportional fonts, options such as this LISTING-only options just do not work. In addition, you show the use of HTMLSTYLE, which you showed in a previous forum posting as well -- this technique will NOT work with ODS PDF. I would suggest that you do the following as a test:
1) Get rid of the HTMLSTYLE references in your PROC REPORT step, as they will only apply to ODS HTML output...not ODS PDF output
2) get rid of the template step completely
3) move your border width controls (it looks to me like you want to get rid of the border entirely??? and your header controls into the PROC REPORT statement:
[pre]
proc report data = VL0608_104R_ADDRESS_DISTR_LST1 nowd split='*'
style(header)={background=white}
style(report)={rules=none frame=void cellspacing=0 borderwidth=0}
style(summary)={background=graycc} split='*';
[/pre]
You can investigate the various interactions and possibilities of using RULES and FRAME and CELLSPACING by reading the ODS DOCUMENTATION under the topic: "Style Attributes and Their Values". (I changed "grayff" to "white", since that is the color represented by "grayff").
4) You cannot simulate an OVERLINE using HTMLSTYLE with ODS PDF, as previously explained. As an alternative, I have highlighted your summary line with a background color of graycc. You could choose an alternate type of highlighting, such as:
[pre]
style(summary)={font_weight=bold font_style=italic font_size=14pt}
[/pre]
Because the spacing = 50, spacing = 20 and spacing=10 will not work for ODS PDF, I would suggest you use cellwidth to increase the width of individual columns. Text will flow appropriately when you use ODS PDF, RTF and HTML, you do not need the FLOW option, as shown in the example below. Remember that with ODS PDF, you can also use the following SAS system options, in an OPTIONS statement to impact ODS PDF output:
[pre]
options orientation=landscape topmargin=".5in" bottommargin=".5in"
leftmargin=".5in" rightmargin=".5in";
[/pre]
cynthia
*** Example of automatic FLOW of text;
[pre]
options nodate nonumber center orientation=portrait
leftmargin=".5in" rightmargin=".5in"
topmargin=".5in" bottommargin=".5in";
%let long = Twas brillig and the slithy toves did gyre and gimble in the wabe.;
%let long2 = All mimsy were the borogroves and the momeraths outgrabe.;
** make some "big variables" in a copy of SASHELP.CLASS;
data makebig;
length bigvar bigvar2 bigvar3 $250 ;
set sashelp.class;
bigvar = catx(' ', name,"&long","&long2");
bigvar2 = bigvar;
bigvar3 = bigvar;
run;
ods pdf file='c:\temp\flow_cellwidth.pdf' ;
proc report data=makebig(obs=2) nowd split='*'
style(header)={background=white}
style(summary)={font_weight=bold font_style=italic background=graycc};
title '1a) Control Flow with CELLWIDTH';
column name age height weight bigvar bigvar2 bigvar3;
define bigvar / "CW=2in"
style(column)={just=l font_size=10pt font_face='Helvetica'
cellwidth=2.0in};
define bigvar2 / "CW=1in"
style(column)={just=l font_size=10pt font_face='Helvetica'
cellwidth=1.0in};
define bigvar3 / "CW=1.5in"
style(column)={just=l font_size=10pt font_face='Helvetica'
cellwidth=1.5in};
rbreak after / summarize;
run;
ods _all_ close;
[/pre]