ODS LAYOUT - Border

[MPaola]

I'm using ODS LAYOUT to create a pdf document which must show 4 graphs in a page with a blu border around my ods layout.
How can i show this blu border?
thanks
MPaola

[DanO_sas_com]

Absolute layout supports the border attributes, but at this time Gridded layout does not. Here is an example of using Absolute layout.
ods _all_ close;
ods path work.templat(update) sashelp.tmplmst(read);
proc template;
define style styles.mystyle;
parent = styles.printer;
style LayoutContainer /
borderwidth=1mm
borderstyle=solid
bordercolor=blue;
style layoutRegion /
borderwidth=0mm
bordercolor=_undef_;
end;
run;

goptions reset=all;

ods pdf file="test.pdf" style=Styles.mystyle;
ods layout start width=6.25in height=6.25in;
ods region x=.125in y=.125in width=3in height=3in;
proc gchart data=sashelp.class;
vbar age;run;

ods region x=3.125in y=.125in width=3in height=3in;
proc gchart data=sashelp.class;
vbar age;run;

ods region x=.125in y=3.125in width=3in height=3in;
proc gchart data=sashelp.class;
vbar age;run;

ods region x=3.125in y=3.125in width=3in height=3in;
proc gchart data=sashelp.class;
vbar age;run;

ods layout end;
ods pdf close;