Defining Multiple Style Formats for use in Proc Print

[Gloveman71]

I currently use SAS 9.4 in a Grid.

Please refer the the listed link,  my question pertains to this:  http://support.sas.com/kb/23/353.html

Please see the Proc Print example,  Can you define multiple format styles for use in Proc Print on different variables?  I would like to use the background style format on different variables based on the value of the variable.  I have also listed the example below for easier explanation:

   ods html body='temp.html';

   proc format;
     value temp 11=red
                12=purple
                13=orange
                14=pink
                16=yellow
                other=blue;
   run;

   ods html body='temp.html';

   proc print data=sashelp.class ;
     var age / style={background=temp.};
     var sex height weight;
   run;

   ods html close;

Hope I have explained this properly,

Thanx for any help,

Jim Glover

[Tim_SAS]

Is this what you want?

ods html file="test.html";

proc format;
   value agef
      11-13='red'
      13<-high='cyan';
	value $sexf
		M='yellow'
		F='pink';
      

proc print data=sashelp.class;
   var name;
   var age / style={background=agef.};
   var sex / style={background=$sexf.};
   var height / style={background=black color=white};
   var weight / style={background=black color=yellow};
   run;
ods html close;

[Gloveman71]

Yes, Thanx for the assist. I setup some additional formats and they worked great!!!

Thanx again,

Jim Glover