how to generate this string

[JP1234]

start='01feb2017'd;

end='05may2018'd;

I want to generate a string

IND_FEB17,IND_MAR17, IND_APR17, IND_MAY17,.....IND_ARP18, IND_MAY18

how to use a marcro to do that?

Thanks.

Jeff

[novinosrin]

Very simple with datastep syntax than macro syntax IMHO

data w;
do i=0 to intck('month','01feb2017'd,'05may2018'd);
list=catx('_','IND',put(intnx('month','01feb2017'd,i),monyy.));
output;
end;
drop i;
run;

proc sql;
select list into :list separated by ','
from w;
quit;
%put &=list;

[JP1234]

Thanks! Perfect!

[novinosrin]

You can macrotise the above with a macro wrapper like

dm log 'clear';
%macro t(start='01feb2017'd,end='05may2018'd);
%global list;
data w;
do i=0 to intck('month',&start,&end);
list=catx('_','IND',put(intnx('month',&start,i),monyy.));
output;
end;
drop i;
run;
proc sql noprint;
select list into :list separated by ','
from w;
quit;
%mend t;
%t
%put list=&list;

[ballardw]

It may help to tell us how you intend to use the resulting string.

If it is supposed to represent a list of data sets or variables you may be able to us list notation such as

IND_:   all variables or datasets that start with ind_

Ind_feb17 - ind_may18  possibly, depends on actual values of other dataset names or variables as month names or abbreviations are a not well thought out value for sorting/selection in order

ind_feb17 -- ind_may18 (adjacent variables in a set)

[mkeintz]

I agree with @ballardw that you might get more benefit from the forum if you let us know why you need this list.  There may be many shortcuts that don't require itemizing the elements of the list.

However, this can be done fairly directly in a macro:

%macro monyy_list(prefix=,start=,end=);
  %global strng;
  %do d=%sysfunc(inputn(&start,date9.)) %to %sysfunc(inputn(&end,date9.));
    %let strng=&strng &prefix%sysfunc(putn(&d,monyy5.));
    %let d=%sysfunc(intnx(month,&d,1));
  %end;
%mend monyy_list;

%monyy_list(prefix=IND_,start=01feb2017,end=05may2018);
%put &=strng;

The %sysfunc macro function is a way to invoke regular SAS functions in the macro environment.  In this case,

1. The INPUTN function reads a value as if into a numeric variable.
2. The PUTN function write a number as text according to the specific format.
3. The INTNX function advances the date value (in macrovar D) by 1 month.

[JP1234]

Thanks!

[Ksharp]

data x;
start='01feb2017'd;
end='05may2018'd;
length want $ 800;
do i=start to end ;
 if month(i) ne month then do;
   want=catx(',',want,cats('IND_',put(i,monyy5.)));
 end;
 month=month(i);
end;

put want=;
run;

[PeterClemmensen]

I'm interested. Why do you want a string like that?

[JP1234]

Thank you very much. It works!

The string contains field names form a dateset which is updated monthly with a new  field name added to it.

Jeff

[andreas_lds]

---

@JP1234 wrote:

Thank you very much. It works!

The string contains field names form a dateset which is updated monthly with a new  field name added to it.

Jeff

---

Adding fields every month is only necessary if the data is stored in variable-names. That is bad design and fixing it almost always allows easier using of the data.