Hi @Madhu_Kappala,
You can back into it, I think, by finding all of the information maps first, then using PROC INFOMAPS to list the tables.
Example:
/* Specify your metadata folder here. This is the folder that */
/* contains the information map definitions */
%let folder = /Shared Data/Maps;
/* NOTE: when using this LIBNAME statement in a batch environment, */
/* you might need to add metadata host and credentials information. */
/* When running from SAS Enterprise Guide, it should not be */
/* necessary; your metadata identity will be used automatically. */
/* Note that the report will contain only those Information Maps */
/* for which you have Read access permissions. */
libname imaps infomaps
mappath="&folder"
aggregate=yes
/* use already-established metadata connection */
metacredentials=no
/* uncomment the following if running in batch/DMS */
/*****************
host=metadatahost.com
port=8561
user=yourId
pw="yourPassword"
******************/
PRESERVE_MAP_NAMES=YES;
footnote;
/* Report of information maps in the selected folder */
proc print data=sashelp.vinfomp noobs label;
var mapname description;
label mapname = "Name" description = "Description";
title "Information Maps in &folder";
run;
Example result:
![imap.jpg imap.jpg](https://communities.sas.com/t5/image/serverpage/image-id/35638iE4F69700BC6328A0/image-size/large?v=v2&px=999)
Then PROC INFOMAPS:
proc infomaps;
update infomap "Cars" mappath="/Shared Data/Maps";
list datasources;
run;
Example output:
Total datasources: 1
Data source: Sample Data.CARS_1993
ID: CARS_1993
Name: CARS_1993
Description:
More in these blog posts:
Chris