PROC SGPLOT plotting values that are not in set?

[TheSASNovice]

I'm manipulating an existing dataset using PROC TIMESERIES - specifically aggregating 5 minute values into hours and doing this many days.

When I try plotting the hours there are some values being plotted that are not supposed to be there, and I can't find them in the dataset either.

PROC TIMESERIES data=examlib.china out=a3;
id dato_tid interval=hour
accumulate=total
setmissing=missing; 
var antal;
run;
data a4; 
set a3;
hh=hour(dato_tid);
dd=weekday(datepart(dato_tid));
run;
PROC SGPLOT data=a4;
series x=hh y=antal;
run;

getting this plot, with wrong values also printed in

Trying to locate these values in the dataset yields no results.

PROC PRINT data=a4;
var antal;
where hh=10 and antal<600;
run;

The only thing it finds is the missing values (there is a day with missing values), but none of the plotted values which are non-zero.

Any ideas what I'm doing wrong here? Any and all help much appreciated 🙂

[PGStats · Accepted solution]

You are just looking at the line joining consecutive days. Try this instead;

data a4; 
set a3;
hh=timepart(dato_tid);
dd=datepart(dato_tid);
run;

PROC SGPLOT data=a4;
series x=hh y=antal / group=dd lineattrs=(pattern=solid color=blue);
run;

(untested)

[TheSASNovice]

Fantastic. Thanks so much mate! 🙂

I guess the only thing I need to fix is the xaxis, as it should ideally be showing hours. I will try to work in this 🙂

These are hourly traffic stats btw, for anyone interested 🙂

EDIT:

Converting to hours was easy. One small change in code:

data a4; 
set a3;
hh=timepart(dato_tid);
dd=datepart(dato_tid);
hh=hh/3600; *convert to hour format by dividing by seconds in hour;
run;

PROC SGPLOT data=a4;
series x=hh y=antal / group=dd lineattrs=(pattern=solid color=blue);
run;

Thanks 🙂