How to creat dummy variables for a series of cont. var. by using macro

[RobertWang]

Hello,

I have a dataset which consists of over 100 continuous variables.

What I want to do is to creat corresponding dummy variables in the same dataset according to their medians.

Because of the large number of variables, I'd like to do it by means of %macro.

In the attached, I first input a dataset as an example and provide some codes (syntax) that I've tried. 

I have basic ability in programming, but not in coding macro syntax at all.

Could you please do me a favor?  I apprecite your efforts and help.

[PaigeMiller]

What I want to do is to create corresponding dummy variables in the same dataset according to their medians. 

What happens after you find the medians of each variable? What is the next step? How do you go from medians to dummy variables?

I doubt a macro is needed here, but the answer really depends on what you do with the medians.

[mkeintz · Accepted solution]

@RobertWang

I don't think you need a macro.  What you really need is

1. A list of variables to pass through proc means processing (i.e.  VARS TGFB2--COH1_208834; in your case - NOTE THE DOUBLE DASH)
2. Tell the proc means to generate medians and assign them to a corresponding list of names. 
3. Run a data step comparing the original list of variables to the corresponding list of medians, generating yet another corresponding list of dummy variables.

Here's an example using sashelp.class:

proc means data=sashelp.class noprint ;
  vars age -numeric- weight;
  output out=meds (drop=_type_ _freq_) median= p50= / autoname;
run;

data want;
  set sashelp.class ;
  if _n_=1 then set meds;
  array vars {*} age--weight ;
  array meds {*} age_median--weight_median;
  array p50  {*} age_p50--weight_p50;
  do i=1 to dim(vars);
    p50{i}=ifn(vars{i}=.,.,vars{i}>meds{i});
  end;
  drop age_median--weight_median i;
run;

1. The vars statement tells proc means to generate stats on all the numeric variables from age (on the left) through weight (on the right).
2. The output statement tells sas to generate two stats for each variable: median and percentile 50.  Yes, they are the same stat, but the use of the autoname option tells sas to name the new variables as  age_median age_height age_weight and age_p50 height_p50 and weight_p50.  This will be handy in the following data step.
3. The data step defines three "synchronized" arrays.  Each element of the P50 array will be recalculated based on whether the original variable element is greater than its corresponding median.
4. Not the "if _n_=1 then set ..." statement is a way to read the median and p50's and not have them reset to missing in subsequent data step iterations.  I.e. they are "retained".

[RobertWang]

Thank PaigeMiller and mkeintz for your prompt responses.

I can't believe I can get help immediately.

The example provide by mkeintz completely solved my question.

And it's so elegant. (although I still don't understand a part of the program, it works well.)

Thank yo so much for the kind help. 

Wish you a Merry Christmas & Happy New Year !!

Cheers  

[mkeintz]

@RobertWang

Which part of my program that you don't understand yet?  I can edit my answer to clarify.