How to calculate total deposit using base SAS & SQL?

[aman23]

I have a dataset with below data:

i need sum of deposit & sum of withdrawals of each employee

name	money
Andrea	-10000
Mark	149513
Kassidy	-5016
Andrea	17500
Andrea	2500
Jim	100000
Jim	-50
Jim	-50
Jim	-50
Kassidy	-2013

Output should be like this:

name	sum of deposit	sum of withdraws
Andrea	20000	10000
Mark	100000	150
Kassidy	0	7029
Jim	149513	0

[novinosrin]

data have;
input name $	money;
cards;
Andrea	-10000
Mark	149513
Kassidy	-5016
Andrea	17500
Andrea	2500
Jim	100000
Jim	-50
Jim	-50
Jim	-50
Kassidy	-2013
;

proc sql;
create table want as
select name, sum((money>=0)*money) as sumofdeposit,abs((sum((money<0)*money))) as sumofwithdraw
from have
group by name;
quit;

[novinosrin · Accepted solution]

proc sort data=have;
by name;
run;

data want;
set have;
by name;
if first.name then do;
sumofdeposit=0;
sumofwithdraw=0;
end;
sumofdeposit+(money>=0)*money;
sumofwithdraw+(money<0)*money;
if last.name;
sumofwithdraw=abs(sumofwithdraw);
keep name sum:;
run;

[aman23]

why below variables are multiplied?? can you show or explain with the help of any of the observation from data only?

(money>=0)*money;
(money<0)*money;

[novinosrin]

Just converting the values to boolean 1's and 0's  based on the need .

So when 

money>=0)

is true, the value would be 1 and when false the value is 0

And the same for withdrawal expression 

[aman23]

Got it thanks a lot 🙂