Hierarchical data, keep specific observations only

[learn2]

This is a previously unanswered question, hoping someone can help!

If I have the following data let’s say with some duplicate injury dates. My goal is to keep the most severe of the duplicate injury dates along with the other unique injury records. The hierarchy is as follows: Home(least severe)<Clinic<Hospital(more severe). So I would keep only the Clinic observation for ID 1, but for ID 2 I would keep the Clinic on the Feb 1st injury date (as it is more severe than Home for the same injury date) and the Feb 6th date since it’s another injury date and not a duplicate. How do I code this?

ID	Injury date	Location of injury
1	Jan02,2007	Home
1	Jan02, 2007	Clinic
2	Feb01,2000	Home
2	Feb06,2000	Hospital
2	Feb01,2000	Clinic

[VDD · Accepted solution]

You are correct that the question has been asked before the solution below has changes that take into account your requirements for the date criteria.

data have;
input ID $ Injurydate:$20. Locationofinjury $;
infile cards dlm=' ';
cards;
1 Jan02,2007 Home
1 Jan02,2007 Clinic
2 Feb01,2000 Home
2 Feb06,2000 Hospital
2 Feb01,2000 Clinic
;

data help;
set have;
if Locationofinjury="Home" then severity=1;
else if Locationofinjury="Clinic" then severity=2;
else if Locationofinjury="Hospital" then severity=3;
else severity=.;
run;

proc sort data=help;
by ID injurydate severity;
run;

data want(drop=severity);
set help;
by ID injurydate severity;
if last.injurydate;
run;