I am going to make suggestion that you do not use character values of 'Yes' 'Y' 'True' 'T' 'No' 'N' 'False' or 'F' for variables that only take on two values when present. If you read such data as numeric with 1 for 'Yes' 'True' or similar and 0 for 'No' 'False' or similar you can accomplish many things easily.
This does require some manipulation of the data, either when read (easy when reading text files) or adding additional variables with the numeric values (routine and tedious but simple).
First, please do not provide data as pictures.l We can't code against pictures. At least provide text.
This is an example of using custom informats and formats to read and display values and create some variables from the read data that are similar to typical things done with a number of YES/NO type variables.
Proc format;
/* values to read are yes, y, no or n,
if other than those it should be missing
*/
invalue Yesnoonly (upcase)
'YES','Y'=1
'NO','N' =0
other =.
;
/* values are yes or Y and if not present
actually mean no (or not selected)
such as check box data on forms
*/
invalue YesOnly (upcase)
'YES','Y'=1
other=0
;
/* values are like yes, y, no, n
and have a special value for not entered,
not applicable or similar
which would depend on your data documentation
this uses x
*/
invalue ynx (upcase)
'YES','Y'=1
'NO','N' =0
'X' =.X
other= .
;
value yesnoonly
1='Yes'
0='No'
.='Missing'
;
value yesonly
1='Yes'
0=' '
;
value ynx
1='Yes'
0='No'
.x='N/A'
.='Missing'
;
run;
/* example reading data*/
data example;
input x1 :yesnoonly. x2 :Yesonly. x3 :ynx.;
datalines;
y yes yES
n . no
Yes abc x
n n n
yes YES YES
;
/* example using the numeric x1,x2, x3 numerics*/
data want;
set example;
NumberYes = sum(of x1-x3);
NumberResponses = n(of x1-x3);
MeanYes = mean(of x1-x3);
Anyyes = (max(of x1-x3) = 1);
Anymissing = (nmiss(of x1-x3)=1);
run;
Proc means data=want mean min max sum n;
var Numberyes NumberResponses MeanYes Anyyes Anymissing;
run;
/* and display similar to original values*/
proc print data=example noobs;
var x1 x2 x3;
format x1 yesnoonly. x2 Yesonly. x3 ynx.;
run;
Proc format is used to create custom informat and formats. INVALUE is used to read values. The value lists have the text to be read on the left of the = and the result on the right. The option UPCASE means to make the value uppercase before comparing to the list values. This can be quite helpful with manually entered data or any source that is not consistent with the case of characters. The different invalue sets have a brief description of the kind of data to read and how it is treated. There are also custom formats, created with Value statement that will show the numeric values as text similar to what was read.
The first data step uses the different informats to read values. Note that for inline data in the datalines that period (.) would be read as missing value.
Then we create in the second data step per line summary values (this is the core of your question). SUMming is much simpler that a slew of If / then /else with a number of variables. It demonstrates one of the uses of varaible lists with the "of x1 - x3" syntax. If you have variables with a common name base, such as X or Disease, followed by sequential integers you can reference them in many places with the X1-X(n) where n is the last of the list you want. In some functions you precede the list with "of" to make sure the function understand you want the list and not the subtraction that "x1-x3" could also mean. Notice that if you have 50 variables named X1 to X50 the only change needed to get the sum or other summary is to change the 3 to 50. Cannot do anything similar with character variables easily.
The two ANY variables created demonstrate that SAS uses 1/0 as True/False (or yes/no) for results of logical comparisons. The Mean of a 1/0 coded variable is the decimal percentage of 1 values, 0.5 = 50%, and will exclude the missing values in the denominator.
The we use Proc Means as one want to get the summary for those added variables.
The mean of NumberYes of 1.4 is across all this example data that the average number of Yes response is 1.4, the Min of 0 means that at least one record had no yes and the max of 3 indicates that at least one record had 3 yes, sum of 7 means that across all the variables and responses there were 7 total yes entered.
The mean for NumberResponses of 2.8 means that the average number of non-missing values was 2.8. The sum of 14 is a number of non-missing responses (out of 15 the n*number of variables considered)
The mean for Anyyes of 0.6 means that 60% of the records had at least one Yes recorded.
The mean for Anymissing of 0.2 means that 20% of the records had at least on missing value.
The proc print demonstrates using the formats to display original values but a bit more consistent than the original spelling.
Since you did not provide text of the variables and I am too lazy to type that many names that long I am not going to show exact code to recode your existing data. Some like:
data need;
set yourdatasetname;
array d (*) <list your disease variable names of character values here>;
array n (*) <matching list of numerical variables here>;
/*or Array n(15) ; the number is the number of variables and creates numeric variables n1 - n15*/
do i=1 to dim(d);
n[i] = input(d[i], yesonly.);
end;
NumberYes = sum(of n(*));
run;
Arrays are shorthand to reference similar variables. The summary functions will treat "of arrayname(*)" as a list of all variables in the array.
You can use other lists.
