combine Barchart with Circles

[pmksasbi]

HI ,

can anyone please give some example code for the vertical bar graph with circles plotting on it.

Thanks,

Mahesh

[Reeza]

What would that even look like? What would be on the axis? Is it dual axis?

[pmksasbi]

Sample

x-axis with description of city , y axis with dollar, right side with no of assigned clients

[djrisks]

Hello,

Here is some example code that you can use:

data testdata;
  length city $9;
  city = "London"; dollar = 50; scatter = 45; output;
  city = "Dubai"; dollar = 40; scatter = 35; output;
  city = "New York"; dollar = 20; scatter = 25; output;
  city = "Las Vegas"; dollar = 60; scatter = 30; output;
run;

proc template;
  define statgraph barwithcircle;
    begingraph;
	  layout overlay;
	    barchart x = city y = dollar;
		scatterplot x = city y = scatter / markerattrs = (size = 20 color = orange symbol = circlefilled);
	  endlayout;
	endgraph;
  end;
run;

proc sgrender data = testdata template = barwithcircle;
run;
  

The code produces the graph below.

[Reeza]

proc sgplot data=testdata;
vbarparm category = city response=dollar;  *bar graph;
scatter x= city y=clients / y2axis; *scatter plot;
run;

See the section in the docs titled Basic-Compatible Bar Chart Examples for various other examples here

https://documentation.sas.com/doc/en/vdmmlcdc/1.0/grstatproc/n121lznfa1jnlvn1q95t0r5sd2gq.htm#p11meh...

---

@pmksasbi wrote:

Sample

x-axis with description of city , y axis with dollar, right side with no of assigned clients

---

[pmksasbi]

thank you all

[djrisks]

You're welcome. I also believe that my answer should have been marked as the solution since I created the data and answered it first.

[pmksasbi]

i am sorry, since i marked it . i am unable to make any changes

[Reeza]

---

@pmksasbi wrote:

i am sorry, since i marked it . i am unable to make any changes

---

Actually it can ben updated, click the three dots beside the post currently marked as solved.

@djrisks As to which solution to mark as correct - the OP should mark the solution that best fits their needs, ie if the SGPLOT solution is simpler that is a valid selection over an SGRENDER solution.

[Ksharp · Accepted solution]

data testdata;
  length city $9;
  city = "London"; dollar = 50; scatter = 45; output;
  city = "Dubai"; dollar = 40; scatter = 35; output;
  city = "New York"; dollar = 20; scatter = 25; output;
  city = "Las Vegas"; dollar = 60; scatter = 30; output;
run;

proc sgplot data=testdata noautolegend;
vbar city/response=dollar;
vline city/response=scatter LINEATTRS=(thickness=0) MARKERATTRS=(size=20 symbol=circlefilled color=orange) markers;
run;