Using gbarline, is there a way to plot 2 lines on same graph?

[deleted_user]

I'd like to show the change in use of something over time (left y axis (bar)=% use; x-axis= year) by the growth in # of something else (right y-axis (line)). But, there are two subgroups for the line plot. Is there any way to get this on 1 graph rather than have a separate graph for each subgroup of axis 3?

Thanks!

[DanH_sas]

What version of SAS are you using?

[deleted_user]

Windows 9.1.3 SP 4

[DanH_sas]

Hey Julie,

In SAS 9.2, this is very simple to do. In 9.1.3, I had to take a more creative approach. Try the sample below and see if you can make it work for you.

Thanks!
Dan

/* summarize your data */
proc means data=sashelp.class noprint;
class age sex;
var weight height;
output out=class mean=;
run;

/* Adjust some fields for correct plotting */
data class2;
set class;
if (_type_ ne 2) then weight=.;
if (_type_ ne 3) then height=.;
if (sex eq " ") then sex="M";
run;

symbol1 i=needle width=40 color=blue;
symbol2 i=join;
axis1 offset=(5pct, 5pct) minor=none;
axis2 order=(0 to 150 by 25) offset=(0,0);
axis3 order=(0 to 80 by 20) offset=(0,0);

proc gplot data=class2;
plot weight*age / haxis=axis1 vaxis=axis2;
plot2 height*age=sex / vaxis=axis3;
run;

[deleted_user]

Thanks -- I will give it a shot!

[deleted_user]

btw, can you tell me the code for version 9.2? I may have access to it...thx

[DanH_sas]

In 9.2, gbarline supports multiple plot lines. Therefore, you can pull your subgroup into separate columns and use gbarline. Here's a simple example:

data class;
set sashelp.class;
if (sex="F") then female=height;
if (sex="M") then male=height;
run;

proc gbarline data=class;
bar age / sumvar=weight;
plot / sumvar=female;
plot / sumvar=male;
run;