Standard Error (SE) in 'proc sgplot'

[DmytroYermak]

Hi all,

Could you please help to code the 'Standard Error' for the gsplot. The plot has to be as below. What should be a standard of the dataset? What are the options for proc sgplot?

[DanH_sas]

The main options you want to use on the VLINE statement are the following:

1. LIMITSTAT = CLM | STDERR | STDDEV -- for your case, use STDERR

2. NUMSTD = <number> -- This is a multiplier for STDERR or STDDEV. The default is 1, which mean you would get one standard error in your case.

3. LIMITS = UPPER | LOWER | BOTH -- the default is BOTH, just like in your picture.

Here is a simple example:

proc sgplot data=sashelp.class;
vline age / response=weight stat=mean limitstat=stderr numstd=2;
run;

You can also modify the visual attributes of the error bars using the ERRORATTRS option.

Hope this helps!

Dan

[DmytroYermak]

Thank you for the reply! Could you please say how to modify your code to draw two lines: one for 'male', another for 'female'.

And another question: if I have SE calculated in previous steps (this is an obligate rule) how to put SE on the plot in this case?

[PGStats · Accepted solution]

Try something like:

proc sql;
create table classGraph as
select 
    sex, 
    age, 
    mean(weight) as meanWeight, 
    mean(weight) - std(weight) as lowStdWeight,    
    mean(weight) + std(weight) as highStdWeight
from sashelp.class
group by sex, age;
quit;

proc sgplot data=classGraph;
scatter x=age y=meanWeight / 
    yerrorlower=lowStdWeight yerrorupper=highStdWeight group=sex;
series x=age y=meanWeight / lineattrs=(pattern=solid) group=sex;
run;

[PeterClemmensen]

What does your data look like?

Perhaps something like this example?

http://support.sas.com/kb/42/542.html

[DmytroYermak]

Thank you for the last link. I used it:

[PGStats]

invalue defines an INFORMAT. You need a VALUE statement to define a format in proc format.