Provide some minimal data in the form of a data step and the code you are currently using and we'll see if we can get what you want. It helps to know what you've done so far.
Modifying the example from http://support.sas.com/kb/45/056.html
The code below 1) adds another statistic 2) modifies the position of the first value and 3) adds value and position for second statistic to the annotate data set
/* Sum the total sales by product for each country */
proc sort data=sashelp.prdsale out=prdsale;
by product country;
run;
proc means data=prdsale noprint;
by product country;
var actual;
output out=meansout sum=actual_sum std=sTD; /*<= new statistic*/
run;
/* Create an Annotate data set to draw */
/* the summed values for each subgroup. */
data barlabel;
length function color $8 text $ 16;
retain xsys ysys '2' color 'black' when 'a';
set meansout;
function='label';
midpoint=product;
subgroup=country;
position='A'; /*<=change position from original*/
text=trim(left(put(actual_sum,dollar8.0)));
output; /*<= force output of first part of labe text*/
function='label'; /* from here down add second value for same input record*/
midpoint=product;
subgroup=country;
position='D'; /*complementary position to above*/
text=cats('STD=',put(std,dollar8.2));
output;
run;
/* Define the title */
title1 "Label the Subgroups in a Horizontal Bar Chart";
/* Define the axis characteristics */
axis1 label=(angle=90 "Product")
value=(justify=right);
axis2 label=("Actual Sales")
order=(0 to 160000 by 40000)
minor=(n=3);
/* Define legend options */
legend1 frame;
/* Generate the graph */
proc gchart data=sashelp.prdsale;
hbar product / subgroup=country
sumvar=actual
legend=legend1
nostats
maxis=axis1
raxis=axis2
annotate=barlabel;
format actual dollar8.0;
run;
quit; title;
