Hi:
I did not find a Tech Support note yet, but if you just heard back from Tech Support, it does take some time for new notes to go through their "process".
In the meantime, I figure Tech Support told you that your template change will work with ODS HTML3 (which generates W3C HTML 3.2 compliant HTML tags) as opposed to regular ODS HTML (which generates W3C HTML 4.0 compliant HTML tags). So until the Tech Support note comes out, I thought I would post this workaround. It's a revision to the template code in this note:
http://support.sas.com/kb/23/435.html
using both ODS HTML3 and ODS HTML to show how the HTML 3.2 output uses the contentsize attribute and how the HTML 4.0 output does not. I believe the reason that the older ODS HTML3 works and the newer ODS HTML does not is that the older ODS HTML3 destination did things slightly differently than the newer ODS HTML destination.
There was also a previous forum posting on this topic:
http://support.sas.com/forums/thread.jspa?threadID=7301 (but no workaround). I believe another approach would be to change the tagset template for ODS HTML -- but I find the ODS HTML3 method easier for my students to understand.
If you need to generate an in-line style section, you can always modify your ODS HTML3 invocation to use the STYLESHEET option:
[pre]
ods html3 path='c:\temp' (url=none)
file='ts3sbod.html'
contents='ts3stoc.html'
frame='ts3sfrm.html' style=styles.test
stylesheet;
[/pre]
cynthia
[pre]
ods path work.testtemp(update)
sasuser.templat(update)
sashelp.tmplmst(read);
proc template;
define style styles.test;
parent=styles.default;
style Frame from Document /
contentposition = L
bodyscrollbar = auto
bodysize = *
contentscrollbar = auto
contentsize = 50%
framespacing = 1
frameborderwidth = 4
frameborder = on;
end;
run;
** ODS HTML will NOT use CONTENTSIZE attribute;
ods html path='c:\temp'(url=none)
file='ts4bod.html'
contents='ts4toc.html'
frame='ts4frm.html' style=styles.test;
** ODS HTML3 WILL use the CONTENTSIZE attribute;
ods html3 path='c:\temp' (url=none)
file='ts3bod.html'
contents='ts3toc.html'
frame='ts3frm.html' style=styles.test;
proc print data=sashelp.shoes(obs=2);
run;
proc print data=sashelp.class(obs=3);
run;
ods _all_ close;
[/pre]