How to let markers for mean and median to locate at the correct points

[Cingchih]

How to let markers for mean and median to locate at the correct points?

Any help would be greatly appreciated!

my code:

proc means data=sashelp.cars min max mean median;
class type origin;
var mpg_city;
ods output summary=a;
run;

ods graphics/ imagefmt=png width=800px height=600px;
proc sgplot data=a;
highlow x=origin high=MPG_city_max  low=MPG_City_min  /  group=type type=bar  groupdisplay=cluster highlabel=MPG_city_max  
                                            lowlabel=MPG_City_min  labelattrs=(size=10) barwidth=1 clusterwidth=0.8   lineattrs=graphoutlines ;
scatter x=origin y=MPG_city_mean / group=type markerattrs=(symbol=circlefilled size=10 color=red) ;
scatter x=origin y=MPG_city_median /group=type markerattrs=(symbol=Diamondfilled size=10 color=red) ;
xaxis display=(nolabel noticks) valueattrs=(size=12);
yaxis label="Mpg City" labelattrs=(size=12) valueattrs=(size=12);
run;
ods graphics off;

my result:

[Ksharp · Accepted solution]

Add  groupdisplay=cluster  in it.

proc means data=sashelp.cars min max mean median;
class type origin;
var mpg_city;
ods output summary=a;
run;

ods graphics/ imagefmt=png width=800px height=600px;
proc sgplot data=a;
highlow x=origin high=MPG_city_max  low=MPG_City_min  /  group=type type=bar  groupdisplay=cluster highlabel=MPG_city_max  
                                            lowlabel=MPG_City_min  labelattrs=(size=10) barwidth=1 clusterwidth=0.8   lineattrs=graphoutlines ;
scatter x=origin y=MPG_city_mean / group=type markerattrs=(symbol=circlefilled size=10 color=red) 
 groupdisplay=cluster ;
scatter x=origin y=MPG_city_median /group=type markerattrs=(symbol=Diamondfilled size=10 color=blue) 
 groupdisplay=cluster ;
xaxis display=(nolabel noticks) valueattrs=(size=12);
yaxis label="Mpg City" labelattrs=(size=12) valueattrs=(size=12);
run;

[Cingchih]

thank you.