Exporting student panel graphs to RTF

[JulieM]

Hi,

I am running PROC GLIMMIX for a number of response variables (using a BY statement) and would like to save just the StudentPanel graphs of each of the BY run in one RTF file. Is this possible in SAS?

Thanks.

[Reeza]

Sure can.

Use ODS SELECT to find the name of the graph, I'm going to assume it's STUDENTPANEL in this example.

ods rtf file='C:\temp\want.rtf' style=statistical;

ods select StudentPanel;
proc Glimmix ...

run;
ods select all;

ods rtf close;

[JulieM]

Thanks!

But does this mean that if I want to save model results of all runs in one file (e.g., fit statistics, test of fixed effects) and studentpanel graphs of all runs in another file, I would have to run Proc GLIMMIX twice?

ods rtf file ="M:\model.rtf";

ODS EXCLUDE Classlevels LSMeans;
Proc GLIMMIX data=pheno;
by response;

run;

ods select all;
ods rtf close;

ods rtf file ="M:\panels.rtf";
ods select studentpanel;
proc GLIMMIX data=pheno plots=studentpanel;
by response;

run;

ods select all;
ods rtf close;

[Reeza]

AFAIK that would be the easiest method, but the SAS guru's may have another solution to direct the output to specific files. 

[Reeza · Accepted solution]

It looks like you can create the destinations with an ID and then control the output to each RTF file.

ods rtf (id=1) file='/folders/myfolders/want1.rtf' style=journal;
ods rtf (id=2) file='/folders/myfolders/want2.rtf' style=journal;

ods rtf (id=1) select ResidualPlot;
ods rtf (id=2) select parameterEstimates;

proc reg data=sashelp.class;
model weight=age height;
run;
ods select all;

ods rtf (id=1) close;
ods rtf (id=2) close;

[JulieM]

Perfect!

You're an angel!

Thanks!

(sorry for all the exclamation marks!)