Webinar SAS y Excel 2021 | Código: Ejemplo Diamante

[Berenice25]

¡Hola!

Les compartimos el siguiente código, ejemplo Diamante💎  titulado Crea una tabla dinámica en Excel del pasado webinar Saliendo de Excel entrando al mundo SAS con fecha del 22 de septiembre del 2021. 

Puedes revisar nuevamente la grabación si tienes alguna duda, te invito a que lo veas en la plataforma de Ask the Expert

Da clic aquí  

Agradecemos tu participación en futuros talleres. Gracias 

¡No te pierdas de las siguientes publicaciones!

Sigue:

/************************************/
/*									*/
/*   SAS - Customer Success Latam 	*/
/*									*/
/************************************/

/************************************/
/*									*/
/*      Webinar: SAS y Excel		*/
/*            22Sept2021            */
/*									*/
/************************************/

/************************************/
/* Expositor: Daniel Vazquez Vargas */
/************************************/


/************************************/
/* 	    Crea un tabla dinámica		*/
/* 		 	  en Excel		 		*/
/************************************/


/************************************/
/* 	Atención!!!						*/
/* 	Este programa fue probado en 	*/
/*  Enterprise Guide 8.3 + 			*/
/*  Excel 10 (64 bits) +			*/
/*  Windows 10 						*/
/************************************/



/*--------*/
/* inicio */
/*--------*/


/* Para acceder a la plantilla (o a el template) TableEditor */


/* referencia la platilla 'tableeditor' en 'support.sas.com' */
Filename tpl url 
	"http://support.sas.com/rnd/base/ods/odsmarkup/tableeditor/tableeditor.tpl";

/* Permite que la plantilla se agregue a la secuencia de búsqueda plantillas del ODS */
Ods path(Prepend) work.templat(update);

%include tpl;


/* Este programa crea una tabla en Excel con los datos de SASHELP.SHOES. Lo crea en la subcarpeta 'temp', pero puede
cambiarla a otra carpeta. En este caso debe prestar mucha atención a todas las referencias a 'temp' de aquí en adelante. */

ods excel file="c:\temp\temp.xlsx" options(sheet_name="zapatillas"); /* nombre del archivo: temp; nombre de la hoja: zapatillas */
Title; Footnote;  /* limpia títulos y pies de página */
proc print data=sashelp.shoes;
run;

ods excel close;


/* Crea la tabla dinámica */

/* Usaremos dos etapas para agregar la tabla dinámica al archivo Excel */

/* Primero: usamos ODS tagsets.TableEditor y algunas opciones para tablas dinámicas, para crear un script con las 
instruciones necesarias. */
/* Segundo: utilizamos el comando X para ejecutar ese script, que agregará la tabla dinámica en el archivo Excel.*/


/* Genera un script y lo ejecuta */

options noxsync noxwait;  /* Las opciones NOXSYNC y NOXWAIT permiten controlar la interacción entre las aplicaciones */
ods tagsets.tableeditor file="c:\temp\PivotTable.js"                                                                                                                                      
/* Cuidado con las barras invertidas dobles... */
  options(update_target="c:\\temp\\temp.xlsx" doc="help"                                                                                                                                 
    output_type="script"                                                                                                                                           
    sheet_name="zapatillas"  
    pivot_sheet_name="Profit Analysis" 
    pivotrow="region"                                                                                                                                              
    pivotcol="product"                                                                                                                                             
    pivotdata="sales"  
    pivotdata_fmt="$#,###" 
    pivot_format="light1"
    pivot_title="Tabla dinámica de prueba" 
);                                                                                                                                             

/* Algo para disparar la creación de una tabla */    
 
data _null_;                                                                                                                                                                          
 file print; 
 put "test";                                                                                                                                                                             
run;                                                                                                                                                                            
                                                                                                                                                                  
ods tagsets.tableeditor close; 


X "c:\temp\PivotTable.js";   /* el misterioso comando 'X' */



/*--------*/
/*  fin	  */
/*--------*/