Tip Semanal 018: Detalles de Tablas SAS

[Berenice25]

En este Tip les mostramos una forma de acceder a detalles de las tablas de una librería. 
Es posible seleccionar las opciones que necesita. Y también el formato en que se presenta. 
Y, como adicional, se pueden utilizar filtros para obtener solamente la información que precisamos.

/****************************************************************************/
/* Genera un reporte con información sobre una o varias tablas.			  	*/
/* Muestra el contenido de 'DICTIONARY.TABLES' utilizando el 				*/
/* procedimiento SQL.														*/
/* Incluye varias opciones del Proc SQL.									*/
/****************************************************************************/


/*-------------------*/
/* inicio del código */
/*-------------------*/

/* Obtiene la librería, el nombre, la cantidad de filas, el tamaño (¡en 2 	*/
/* formatos diferentes!) y el porcentaje de compresión de las tablas de		*/
/* una librería. 															*/


Proc sql;
	Title1 'Información de tablas de la librería SASHELP';
	Title2 'Utiliza un filtro con dos condiciones';
	Title3 'y ordena por dos variables'; /* ¡recordar que las sentencias 'Title' son globales! */
	Select libname, 
		memname, 
		nlobs Label='Cant. de observaciones', /* etiquetas */
		filesize format=SIZEK.,  /* ¡en 2 formatos diferentes! */
		filesize format=SIZEKMG., 
		pcompress Label='Porcentaje de compresión'
	From DICTIONARY.TABLES
	Where LIBNAME = 'SASHELP' /* ¡CUIDADO! No olvidar que el texto es 'case sensitive' */
		and MEMNAME contains 'D' /* contains! */
	Order by filesize desc, memname /* orden descendente de filesize y ascendente de memname */
	;
QUIT;

Title; /* limpia todos los títulos */

/*----------------*/
/* fin del código */
/*----------------*/