Comparativ Histogram mit ineinandergesetzten Bars

[sauer]

Hallo und guten Abend,

lässt sich denn unten gezeigtes Beispiel-Histogramm alleine mit SGPLOT erzeugen oder brauche ich dazu TEMPLATE?

Ich habe das im ODS GD gefunden und würde das gerne in der "University Edition" nachbauen.

Am besten noch mit Dichtekurve drin ...

Danke und viele Grüße

Frank

[GrischaPfister]

Hallo Frank,

geht wahrscheinlich auch in SGPLOT, hier ein einfaches Beispiel für Proc Template mit Sashelp.Class (aus dem GTL Tutorium von der KSFE 2016)

* GP GTL 003_3 *;

Proc Template;
  Define Statgraph gp.gtl003;
    BeginGraph;
      Layout Overlay;
        Barchart x=name y=weight;
        Barchart x=name y=height / 
          barwidth=.5
          fillattrs=(color=cx336699)
        ;
      EndLayout;
    EndGraph;
  End;
Run;

Proc Sgrender data=Sashelp.Class template=gp.gtl003;
  Where sex = "F";
Run;

Hoffe, das hilft schon mal weiter...

Viele Grüße,

  Grischa

[BrunoMueller]

Alle plot Anweisung in SGPLOT werden der Reihe nach übereinander gelegt.

Hier ein Beispiel:

proc sgplot data=sashelp.class;
  vbar age / response=weight stat=mean ;
  vbar age / response=height stat=mean barwidth=0.5;
run;


proc sgplot data=sashelp.class;
  histogram height / group=sex transparency=0.5 ;
run;

[sauer]

Vielen Dank für Eure Hinweise.

SGPLOT hat wohl keine Schnittstelle zu TEMPLATE.

Aber ich habe es nun doch ganz gut hinbekommen 🙂

Viele Grüße

Frank

[BrunoMueller]

Proc SGPLOT übersetzt alles in GTL, diese kann mit TMPLOUT= Option in ein File geschrieben werden.

Beispiel:

proc sgplot data=sashelp.class tmplout="c:\temp\sgplot.sas";
  vbar age / response=weight stat=mean ;
  vbar age / response=height stat=mean barwidth=0.5;
run;

Meine Empfehlung ist, Proc SGPLOT zu verwenden, die Syntax ist einfacher.

Falls SGPLOT etwas nicht kann, was aber mit GTL möglich ist, so kann man mit der TMPLOUT Option schon mal eine Programm Vorlage bekommen, und diese dann anpassen.