BookmarkSubscribeRSS Feed
beverlyobeng
Calcite | Level 5

I would please like help trying to export these frequencies into one big table, instead of 4 seperate tables.  Is there a way to do this in SAS.  Any help would be greatly appreciated. 

 

proc freq data=M;
Tables (sex newrace livingage&year. risk;
run;

 

 

2 REPLIES 2
Reeza
Super User

If it's all one way freqs this the way I do it:

 

/*This code is an example of how to generate a table with 
Variable Name, Variable Value, Frequency, Percent, Cumulative Freq and Cum Pct
No macro's are required
Use Proc Freq to generate the list, list variables in a table statement if only specific variables are desired
Use ODS Table to capture the output and then format the output into a printable table.
*/

*Run frequency for tables;
ods table onewayfreqs=temp;
proc freq data=sashelp.class;
	table sex age;
run;

*Format output;
data want;
length variable $32. variable_value $50.;
set temp;
Variable=scan(table, 2);

Variable_Value=strip(trim(vvaluex(variable)));

keep variable variable_value frequency percent cum:;
label variable='Variable' 
	variable_value='Variable Value';
run;

*Display;
proc print data=want(obs=20) label;
run;

https://gist.github.com/statgeek/e0903d269d4a71316a4e

beverlyobeng
Calcite | Level 5
thank you this was extremely helpful

sas-innovate-2024.png

Available on demand!

Missed SAS Innovate Las Vegas? Watch all the action for free! View the keynotes, general sessions and 22 breakouts on demand.

 

Register now!

What is ANOVA?

ANOVA, or Analysis Of Variance, is used to compare the averages or means of two or more populations to better understand how they differ. Watch this tutorial for more.

Find more tutorials on the SAS Users YouTube channel.

Discussion stats
  • 2 replies
  • 1415 views
  • 2 likes
  • 2 in conversation