calculation of odds ratio in proc mianalyse

[Kyra]

Hi,

I have run the proc mianalyze procedure using the code-

proc mianalyze parms=lgsparms;
modeleffects Intercept age;
run;

and the output i got is below. I am wondering if there is a way to get pooled ORs.

Thanks,

Prerna

SAS Output

LOGISTIC Model Coefficients (First Two Imputations)

The MIANALYZE Procedure

Model InformationPARMS Data SetNumber of Imputations

WORK.LGSPARMS

15

Variance Information (15 Imputations)Parameter Variance DF RelativeIncreasein Variance FractionMissingInformation RelativeEfficiencyBetween Within TotalInterceptage

0.000071563	0.834895	0.834971	1.68E9	0.000091429	0.000091422	0.999994
3.7856008E-8	0.000591	0.000591	3E9	0.000068309	0.000068305	0.999995

Parameter Estimates (15 Imputations)Parameter Estimate Std Error 95% Confidence Limits DF Minimum Maximum Theta0 t for H0:Parameter=Theta0 Pr > |t|Interceptage

-0.984767	0.913767	-2.77572	0.80618	1.68E9	-1.007942	-0.977410	0	-1.08	0.2812
-0.057741	0.024314	-0.10540	-0.01009	3E9	-0.057897	-0.057192	0	-2.37	0.0176

[SAS_Rob · Accepted solution]

Proc MIANALYZE cannot report odds ratios directly because it requires both a point estimate and a standard error as input. LOGISTIC does not produce a standard error for the odds ratio. One thing you could do is to combine the parameter estimates and then compute the combined odds ratios in a data step. This is straightforward for continuous variables as the odds ratio is simply exp(beta) but for categorical variables you will need to make sure and use the PARAM=REF or PARAM=GLM options on the CLASS statement which compares each level against the reference level and is the basis for odds ratios. Something like the example at the bottom of this email would work.



/*Assume that the imputation has already been done*/

data test;

seed=2534565;

do _imputation_=1 to 5;

do a=1 to 3;

do b=1 to 2;

do i=1 to 250;

x1=ranuni(21);

logit=-2 + .05*a+.45*b+.88*a*b;

p=exp(-logit)/(1+exp(-logit));

if ranuni(seed)>p then y=1; else y=0;

output;

end;

end;

end;

end;

run;

proc surveylogistic data=test;

by _imputation_;

class a/param=ref;

model y=a x1;

ods output parameterestimates=parms_ds;

run;





proc mianalyze parms(classvar=classval)=parms_ds;

class a;

modeleffects x1 a;

ods output parameterestimates=mianalyze_parms;

run;



data OR;

set mianalyze_parms;

OR=exp(estimate);

LCL_OR=exp(LCLMean);

UCL_OR=exp(UCLMean);

proc print;

var parm a OR LCL_OR UCL_OR;

run;

[Kyra]

Hi,

I have one follow up question.

I understand that  with multiple imputation we end up with multiple datasets and proc mianalyze helps us to get pooled estimates.

Is there a way to combine multiply imputed datasets into one dataset at the end.

Thanks,

Prerna

[SAS_Rob]

No, there is nothing that will do this directly and there isn't really a widely accepted way you coud do this.

[Kyra]

Thank you very much for quick response.

[ChuksManuel]

Hello,
I know it's been 2 years since you solved this problem.
I get your codes in this example.
What if i had an interaction term. how can i output the Odds ratio. For example, if my model is
model y=a x1 a*x1;
How can i get the OR in this case if both a and x1 are categorical variables.